mirror of
https://git.yoctoproject.org/poky
synced 2026-02-08 01:36:38 +01:00
df214ad1a5
LINKER_HASH_STYLE differs between MIPS and non-MIPS targets. This means that LDFLAGS differs too. LDFLAGS is exported so it influences all task hashes. Unfortunately this means that packages with architecture "all" differ depending on whether they are built for a MIPS or non-MIPS target. This causes a lot of unnecessary churn in the ipk/all directory when switching build targets. The simplest way to fix this is to ensure that LDFLAGS stays the same for architecture "all" packages by clearing it. It shouldn't being used by such packages anyway. (From OE-Core rev: 14f4d016fef9d660da1e7e91aec4a0e807de59ab) Signed-off-by: Mike Crowe <mac@mcrowe.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
42 lines
1.5 KiB
Plaintext
42 lines
1.5 KiB
Plaintext
#
|
|
# This class is used for architecture independent recipes/data files (usally scripts)
|
|
#
|
|
|
|
# Expand STAGING_DIR_HOST since for cross-canadian/native/nativesdk, this will
|
|
# point elsewhere after these changes.
|
|
STAGING_DIR_HOST := "${STAGING_DIR_HOST}"
|
|
|
|
PACKAGE_ARCH = "all"
|
|
|
|
python () {
|
|
# Allow this class to be included but overridden - only set
|
|
# the values if we're still "all" package arch.
|
|
if d.getVar("PACKAGE_ARCH") == "all":
|
|
# No need for virtual/libc or a cross compiler
|
|
d.setVar("INHIBIT_DEFAULT_DEPS","1")
|
|
|
|
# Set these to a common set of values, we shouldn't be using them other that for WORKDIR directory
|
|
# naming anyway
|
|
d.setVar("TARGET_ARCH", "allarch")
|
|
d.setVar("TARGET_OS", "linux")
|
|
d.setVar("TARGET_CC_ARCH", "none")
|
|
d.setVar("TARGET_LD_ARCH", "none")
|
|
d.setVar("TARGET_AS_ARCH", "none")
|
|
d.setVar("TARGET_FPU", "")
|
|
d.setVar("TARGET_PREFIX", "")
|
|
d.setVar("PACKAGE_EXTRA_ARCHS", "")
|
|
d.setVar("SDK_ARCH", "none")
|
|
d.setVar("SDK_CC_ARCH", "none")
|
|
|
|
# Avoid this being unnecessarily different due to nuances of
|
|
# the target machine that aren't important for "all" arch
|
|
# packages.
|
|
d.setVar("LDFLAGS", "")
|
|
|
|
# No need to do shared library processing or debug symbol handling
|
|
d.setVar("EXCLUDE_FROM_SHLIBS", "1")
|
|
d.setVar("INHIBIT_PACKAGE_DEBUG_SPLIT", "1")
|
|
d.setVar("INHIBIT_PACKAGE_STRIP", "1")
|
|
}
|
|
|