mirror of
https://git.yoctoproject.org/poky
synced 2026-02-27 20:09:41 +01:00
c26b8158a2
(From OE-Core rev: 4a8ea471e386adff9b8f8b535589e599c1491fa5) (From OE-Core rev: 0c3dbaa5d62e9ce404d1203c0478512e36ab8136) Signed-off-by: Alexander Kanavin <alexander.kanavin@linux.intel.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
35 lines
1.3 KiB
BlitzBasic
35 lines
1.3 KiB
BlitzBasic
SUMMARY = "System-wide Performance Profiler for Linux"
|
|
LICENSE = "GPLv3+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504 \
|
|
file://src/sp-application.c;endline=17;md5=40e55577ef122c88fe20052acda64875"
|
|
|
|
inherit gnomebase gettext systemd
|
|
|
|
DEPENDS = "glib-2.0"
|
|
|
|
SRC_URI += " \
|
|
file://define-NT_GNU_BUILD_ID.patch \
|
|
file://0001-configure-Add-option-to-enable-disable-polkit.patch \
|
|
file://0001-Disable-check-for-polkit-for-UI.patch \
|
|
file://0001-Avoid-building-docs.patch \
|
|
"
|
|
SRC_URI[archive.sha256sum] = "e6dca325b3014440f457a92db18ffe342a35888db3f0756694a99b9652796367"
|
|
SRC_URI[archive.md5sum] = "9514065dc752105240e5567c13708af4"
|
|
|
|
AUTOTOOLS_AUXDIR = "${S}/build-aux"
|
|
|
|
EXTRA_OECONF = "--enable-compile-warnings"
|
|
|
|
PACKAGECONFIG ?= "${@bb.utils.contains_any('DISTRO_FEATURES', '${GTK3DISTROFEATURES}', 'gtk', '', d)}"
|
|
PACKAGECONFIG[gtk] = "--enable-gtk,--disable-gtk,gtk+3"
|
|
PACKAGECONFIG[polkit] = "--enable-polkit,--disable-polkit,polkit dbus"
|
|
|
|
SOLIBS = ".so"
|
|
FILES_SOLIBSDEV = ""
|
|
FILES_${PN} += "${datadir}/icons/"
|
|
|
|
SYSTEMD_SERVICE_${PN} = "${@bb.utils.contains('PACKAGECONFIG', 'polkit', 'sysprof2.service', '', d)}"
|
|
|
|
# We do not yet work for aarch64.
|
|
COMPATIBLE_HOST = "^(?!aarch64).*"
|