mirror of
https://git.yoctoproject.org/poky
synced 2026-04-20 09:32:13 +02:00
7cf0c30096
It's not uncommon for specific third party modules to use "go" as the product[1]. However, the canonical CPE for the official Go language/runtime is always golang:go[2], so use that explicitly. [1] e.g. https://nvd.nist.gov/vuln/detail/CVE-2023-49292 [2] e.g. https://nvd.nist.gov/vuln/detail/CVE-2023-39320 (From OE-Core rev: fc3e9cce9e1a5aa5dc9a5ad4abdd4eb61f868d37) Signed-off-by: Ross Burton <ross.burton@arm.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
51 lines
1.4 KiB
BlitzBasic
51 lines
1.4 KiB
BlitzBasic
# This recipe is for bootstrapping our go-cross from a prebuilt binary of Go from golang.org.
|
|
|
|
SUMMARY = "Go programming language compiler (upstream binary for bootstrap)"
|
|
HOMEPAGE = " http://golang.org/"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=5d4950ecb7b26d2c5e4e7b4e0dd74707"
|
|
|
|
PROVIDES = "go-native"
|
|
|
|
# Checksums available at https://go.dev/dl/
|
|
SRC_URI = "https://dl.google.com/go/go${PV}.${BUILD_GOOS}-${BUILD_GOARCH}.tar.gz;name=go_${BUILD_GOTUPLE}"
|
|
SRC_URI[go_linux_amd64.sha256sum] = "9c5d48c54dd8b0a3b2ef91b0f92a1190aa01f11d26e98033efa64c46a30bba7b"
|
|
SRC_URI[go_linux_arm64.sha256sum] = "8afe8e3fb6972eaa2179ef0a71678c67f26509fab4f0f67c4b00f4cdfa92dc87"
|
|
SRC_URI[go_linux_ppc64le.sha256sum] = "2ae0ec3736216dfbd7b01ff679842dc1bed365e53a024d522645bcffd01c7328"
|
|
|
|
UPSTREAM_CHECK_URI = "https://golang.org/dl/"
|
|
UPSTREAM_CHECK_REGEX = "go(?P<pver>\d+(\.\d+)+)\.linux"
|
|
|
|
CVE_PRODUCT = "golang:go"
|
|
|
|
S = "${WORKDIR}/go"
|
|
|
|
inherit goarch native
|
|
|
|
do_compile() {
|
|
:
|
|
}
|
|
|
|
make_wrapper() {
|
|
rm -f ${D}${bindir}/$1
|
|
cat <<END >${D}${bindir}/$1
|
|
#!/bin/bash
|
|
here=\`dirname \$0\`
|
|
export GOROOT="${GOROOT:-\`readlink -f \$here/../lib/go\`}"
|
|
\$here/../lib/go/bin/$1 "\$@"
|
|
END
|
|
chmod +x ${D}${bindir}/$1
|
|
}
|
|
|
|
do_install() {
|
|
find ${S} -depth -type d -name testdata -exec rm -rf {} +
|
|
|
|
install -d ${D}${bindir} ${D}${libdir}/go
|
|
cp --preserve=mode,timestamps -R ${S}/ ${D}${libdir}/
|
|
|
|
for f in ${S}/bin/*
|
|
do
|
|
make_wrapper `basename $f`
|
|
done
|
|
}
|