mirror of
https://git.yoctoproject.org/poky
synced 2026-02-28 20:39:39 +01:00
fa3d3c4a17
Fix build with usrmerge enabled:
WARNING: iputils-s20190709-r0 do_package: iputils: alternative target (/usr/bin/ping or /usr/bin/ping.iputils) does not exist, skipping...
WARNING: iputils-s20190709-r0 do_package: iputils: NOT adding alternative provide /usr/bin/ping: /usr/bin/ping.iputils does not exist
ERROR: iputils-s20190709-r0 do_package: QA Issue: iputils: Files/directories were installed but not shipped in any package:
/bin/tftpd
/bin/tracepath
/bin/arping
/bin/clockdiff
/bin/ping
/bin/traceroute6
/sbin/rarpd
/sbin/ninfod
/sbin/rdisc
Please set FILES such that these items are packaged. Alternatively if they are unneeded, avoid installing them or delete them within do_install.
iputils: 9 installed and not shipped files. [installed-vs-shipped]
WARNING: iputils-s20190709-r0 do_package: iputils: alt_link == alt_target: /usr/bin/ping == /usr/bin/ping
(From OE-Core rev: 4b2322e90f6a3a4d2c44145aa85b688f28edddaa)
Signed-off-by: Alex Kiernan <alex.kiernan@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
56 lines
2.0 KiB
BlitzBasic
56 lines
2.0 KiB
BlitzBasic
SUMMARY = "Network monitoring tools"
|
|
DESCRIPTION = "Utilities for the IP protocol, including traceroute6, \
|
|
tracepath, tracepath6, ping, ping6 and arping."
|
|
HOMEPAGE = "https://github.com/iputils/iputils"
|
|
SECTION = "console/network"
|
|
|
|
LICENSE = "BSD & GPLv2+"
|
|
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=55aa8c9fcad0691cef0ecd420361e390"
|
|
|
|
DEPENDS = "gnutls"
|
|
|
|
SRC_URI = "git://github.com/iputils/iputils"
|
|
SRCREV = "13e00847176aa23683d68fce1d17ffb523510946"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>s\d+)"
|
|
|
|
PACKAGECONFIG ??= "libcap libgcrypt rarpd traceroute6"
|
|
PACKAGECONFIG[libcap] = "-DUSE_CAP=true, -DUSE_CAP=false, libcap"
|
|
PACKAGECONFIG[libgcrypt] = "-DUSE_CRYPTO=gcrypt, -DUSE_CRYPTO=none, libgcrypt"
|
|
PACKAGECONFIG[libidn] = "-DUSE_IDN=true, -DUSE_IDN=false, libidn2"
|
|
PACKAGECONFIG[gettext] = "-DUSE_GETTEXT=true, -DUSE_GETTEXT=false, gettext"
|
|
PACKAGECONFIG[rarpd] = "-DBUILD_RARPD=true,-DBUILD_RARPD=false,"
|
|
PACKAGECONFIG[traceroute6] = "-DBUILD_TRACEROUTE6=true,-DBUILD_TRACEROUTE6=false,"
|
|
PACKAGECONFIG[docs] = "-DBUILD_HTML_MANS=true -DBUILD_MANS=true,-DBUILD_HTML_MANS=false -DBUILD_MANS=false, libxslt"
|
|
|
|
inherit meson update-alternatives
|
|
|
|
EXTRA_OEMESON += "--prefix=${root_prefix}/"
|
|
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
ALTERNATIVE_${PN}-ping = "ping"
|
|
ALTERNATIVE_LINK_NAME[ping] = "${base_bindir}/ping"
|
|
|
|
SPLITPKGS = "${PN}-ping ${PN}-arping ${PN}-tracepath ${PN}-traceroute6 ${PN}-clockdiff ${PN}-tftpd ${PN}-rarpd ${PN}-rdisc ${PN}-ninfod"
|
|
PACKAGES += "${SPLITPKGS}"
|
|
|
|
ALLOW_EMPTY_${PN} = "1"
|
|
ALLOW_EMPTY_${PN}-rarpd = "1"
|
|
ALLOW_EMPTY_${PN}-traceroute6 = "1"
|
|
RDEPENDS_${PN} += "${SPLITPKGS}"
|
|
|
|
FILES_${PN} = ""
|
|
FILES_${PN}-ping = "${base_bindir}/ping.${BPN}"
|
|
FILES_${PN}-arping = "${base_bindir}/arping"
|
|
FILES_${PN}-tracepath = "${base_bindir}/tracepath"
|
|
FILES_${PN}-traceroute6 = "${base_bindir}/traceroute6"
|
|
FILES_${PN}-clockdiff = "${base_bindir}/clockdiff"
|
|
FILES_${PN}-tftpd = "${base_bindir}/tftpd"
|
|
FILES_${PN}-rarpd = "${base_sbindir}/rarpd"
|
|
FILES_${PN}-rdisc = "${base_sbindir}/rdisc"
|
|
FILES_${PN}-ninfod = "${base_sbindir}/ninfod ${sysconfdir}/init.d/ninfod.sh"
|