mirror of
https://git.yoctoproject.org/poky
synced 2026-04-30 21:32:13 +02:00
39b5d509a3
When use PACKAGE_CLASSES = "package_deb", and the length of tmpdir is longer than 177, the error occurs during the image generation: /very/long/path/totmp/sysroots/x86_64-linux/usr/bin/dpkg-scanpackages: bad interpreter: No such file or directory The interpreter is perl, and it does exist, this is because the first line: #!/very/long/path/to/perl in the script can't be very long. Create a wrapper for it would fix the problem. [YOCTO #2640] (From OE-Core rev: 7d3281be18567207de8ce2cabce03957bf2cbca8) Signed-off-by: Robert Yang <liezhi.yang@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
83 lines
2.3 KiB
PHP
83 lines
2.3 KiB
PHP
DESCRIPTION = "Package maintenance system for Debian."
|
|
LICENSE = "GPLv2.0+"
|
|
SECTION = "base"
|
|
|
|
INC_PR = "r17"
|
|
|
|
SRC_URI = "${DEBIAN_MIRROR}/main/d/dpkg/dpkg_${PV}.tar.bz2 \
|
|
file://ignore_extra_fields.patch"
|
|
|
|
DEPENDS = "zlib bzip2 perl"
|
|
DEPENDS_virtclass-native = "bzip2-native zlib-native virtual/update-alternatives-native gettext-native perl-native-runtime"
|
|
RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives}"
|
|
RDEPENDS_${PN}_virtclass-native = ""
|
|
|
|
S = "${WORKDIR}/${BPN}-${PV}"
|
|
|
|
PARALLEL_MAKE = ""
|
|
|
|
inherit autotools gettext perlnative
|
|
|
|
export PERL_LIBDIR = "${libdir}/perl"
|
|
PERL_LIBDIR_virtclass-native = "${libdir}/perl-native/perl"
|
|
|
|
EXTRA_OECONF = "--without-static-progs \
|
|
--without-dselect \
|
|
--with-start-stop-daemon \
|
|
--with-zlib \
|
|
--with-bz2lib \
|
|
--without-selinux \
|
|
--without-sgml-doc"
|
|
|
|
do_configure () {
|
|
echo >> m4/compiler.m4
|
|
sed -i -e 's#PERL_LIBDIR=.*$#PERL_LIBDIR="${libdir}/perl"#' ${S}/configure
|
|
autotools_do_configure
|
|
}
|
|
|
|
|
|
DPKG_INIT_POSITION ?= "98"
|
|
do_install_prepend () {
|
|
install -d ${D}/${sysconfdir}/rcS.d
|
|
# this happens at S98 where our good 'ole packages script used to run
|
|
printf "#!/bin/sh
|
|
dpkg --configure -a
|
|
rm -f ${sysconfdir}/rcS.d/S${DPKG_INIT_POSITION}run-postinsts
|
|
" > ${D}/${sysconfdir}/rcS.d/S${DPKG_INIT_POSITION}run-postinsts
|
|
chmod 0755 ${D}/${sysconfdir}/rcS.d/S${DPKG_INIT_POSITION}run-postinsts
|
|
}
|
|
|
|
do_install_append () {
|
|
if [ "${PN}" = "dpkg-native" ]; then
|
|
# update-alternatives doesn't have an offline mode
|
|
rm ${D}${bindir}/update-alternatives
|
|
else
|
|
mv ${D}${bindir}/update-alternatives ${D}${sbindir}
|
|
fi
|
|
}
|
|
|
|
# Create a wrapper for the perl script to avoid the "bad interpreter"
|
|
# error when the tmpdir is longer than 150.
|
|
do_install_append_virtclass-native () {
|
|
tmp=`find ${D}${bindir} -type f -exec grep -m 1 -l '#!/.*/perl-native/perl' {} \;`
|
|
for i in $tmp; do
|
|
create_wrapper $i ${STAGING_BINDIR_NATIVE}/perl-native/perl
|
|
done
|
|
}
|
|
|
|
PROV = "virtual/update-alternatives"
|
|
PROV_virtclass-native = ""
|
|
|
|
PROVIDES += "${PROV}"
|
|
|
|
PACKAGES =+ "update-alternatives-dpkg"
|
|
FILES_update-alternatives-dpkg = "${sbindir}/update-alternatives ${localstatedir}/lib/dpkg/alternatives ${sysconfdir}/alternatives"
|
|
RPROVIDES_update-alternatives-dpkg += "update-alternatives"
|
|
|
|
PACKAGES += "${PN}-perl"
|
|
FILES_${PN}-perl = "${libdir}/perl"
|
|
|
|
BBCLASSEXTEND = "native"
|
|
|
|
|