mirror of
https://git.yoctoproject.org/poky
synced 2026-04-27 12:32:13 +02:00
8834fb44cf
- Drop open_inner.patch - Drop opkg_archive.patch - Remove "remove_test_binaries" function (From OE-Core rev: e795ba18613a3f45a81617207abc68f93039cbe5) Signed-off-by: Alejandro del Castillo <alejandro.delcastillo@ni.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
75 lines
2.8 KiB
BlitzBasic
75 lines
2.8 KiB
BlitzBasic
SUMMARY = "Open Package Manager"
|
|
SUMMARY_libopkg = "Open Package Manager library"
|
|
SECTION = "base"
|
|
HOMEPAGE = "http://code.google.com/p/opkg/"
|
|
BUGTRACKER = "http://code.google.com/p/opkg/issues/list"
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
|
|
file://src/opkg.c;beginline=4;endline=18;md5=d6200b0f2b41dee278aa5fad333eecae"
|
|
|
|
DEPENDS = "libarchive"
|
|
|
|
PE = "1"
|
|
|
|
SRC_URI = "http://downloads.yoctoproject.org/releases/${BPN}/${BPN}-${PV}.tar.gz \
|
|
file://opkg.conf \
|
|
file://0001-opkg_conf-create-opkg.lock-in-run-instead-of-var-run.patch \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "bd13e5dfc1c2536f0c7b2e15f795278e"
|
|
SRC_URI[sha256sum] = "86887852c43457edfff9d8b6d9520f3f1cdd55f25eb600a6eb31e1c4e151e106"
|
|
|
|
# This needs to be before ptest inherit, otherwise all ptest files end packaged
|
|
# in libopkg package if OPKGLIBDIR == libdir, because default
|
|
# PTEST_PATH ?= "${libdir}/${BPN}/ptest"
|
|
PACKAGES =+ "libopkg"
|
|
|
|
inherit autotools pkgconfig ptest
|
|
|
|
target_localstatedir := "${localstatedir}"
|
|
OPKGLIBDIR ??= "${target_localstatedir}/lib"
|
|
|
|
PACKAGECONFIG ??= "libsolv"
|
|
|
|
PACKAGECONFIG[gpg] = "--enable-gpg,--disable-gpg,\
|
|
gnupg gpgme libgpg-error,\
|
|
${@ "gnupg" if ("native" in d.getVar("PN")) else "gnupg-gpg"}\
|
|
"
|
|
PACKAGECONFIG[curl] = "--enable-curl,--disable-curl,curl"
|
|
PACKAGECONFIG[ssl-curl] = "--enable-ssl-curl,--disable-ssl-curl,curl openssl"
|
|
PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl"
|
|
PACKAGECONFIG[sha256] = "--enable-sha256,--disable-sha256"
|
|
PACKAGECONFIG[libsolv] = "--with-libsolv,--without-libsolv,libsolv"
|
|
|
|
EXTRA_OECONF += " --disable-pathfinder"
|
|
EXTRA_OECONF_class-native = "--localstatedir=/${@os.path.relpath('${localstatedir}', '${STAGING_DIR_NATIVE}')} --sysconfdir=/${@os.path.relpath('${sysconfdir}', '${STAGING_DIR_NATIVE}')}"
|
|
|
|
do_install_append () {
|
|
install -d ${D}${sysconfdir}/opkg
|
|
install -m 0644 ${WORKDIR}/opkg.conf ${D}${sysconfdir}/opkg/opkg.conf
|
|
echo "option lists_dir ${OPKGLIBDIR}/opkg/lists" >>${D}${sysconfdir}/opkg/opkg.conf
|
|
|
|
# We need to create the lock directory
|
|
install -d ${D}${OPKGLIBDIR}/opkg
|
|
}
|
|
|
|
do_install_ptest () {
|
|
sed -i -e '/@echo $^/d' ${D}${PTEST_PATH}/tests/Makefile
|
|
sed -i -e '/@PYTHONPATH=. $(PYTHON) $^/a\\t@if [ "$$?" != "0" ];then echo "FAIL:"$^;else echo "PASS:"$^;fi' ${D}${PTEST_PATH}/tests/Makefile
|
|
}
|
|
|
|
RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-arch-config libarchive"
|
|
RDEPENDS_${PN}_class-native = ""
|
|
RDEPENDS_${PN}_class-nativesdk = ""
|
|
RDEPENDS_${PN}-ptest += "make binutils python3-core python3-compression"
|
|
RREPLACES_${PN} = "opkg-nogpg opkg-collateral"
|
|
RCONFLICTS_${PN} = "opkg-collateral"
|
|
RPROVIDES_${PN} = "opkg-collateral"
|
|
|
|
FILES_libopkg = "${libdir}/*.so.* ${OPKGLIBDIR}/opkg/"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
CONFFILES_${PN} = "${sysconfdir}/opkg/opkg.conf"
|