mirror of
https://git.yoctoproject.org/poky
synced 2026-02-07 09:16:36 +01:00
c48354780e
Bumping the revision on linux-yocto-dev to reflect the updated state of -dev. The aufs/yaffs2 features are in place, but -rt is not yet available, so the branches are placeholders for future updates. This has been tested across all supported architectures and reference qemu platforms, as well as with closely coupled userspace packages. We tweak the LICENSE_CHECKSUM as well, since upstream has added an informational note to the file, but the license is otherwise unchanged. (From OE-Core rev: ca3d2db0e87168f3e1d6baa2e691ee0399db81d7) Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
55 lines
2.5 KiB
BlitzBasic
55 lines
2.5 KiB
BlitzBasic
# This recipe tracks the linux-yocto-dev repository as its upstream source.
|
|
# Since this tree is frequently updated, and periodically rebuilt, AUTOREV is
|
|
# used to track its contents.
|
|
#
|
|
# This recipe is just like other linux-yocto variants, with the only difference
|
|
# being that to avoid network access during initial parsing, static SRCREVs are
|
|
# provided and overridden if the preferred kernel provider is linux-yocto-dev.
|
|
#
|
|
# To enable this recipe, set PREFERRED_PROVIDER_virtual/kernel = "linux-yocto-dev"
|
|
|
|
inherit kernel
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
# for ncurses tests
|
|
inherit pkgconfig
|
|
|
|
# provide this .inc to set specific revisions
|
|
include recipes-kernel/linux/linux-yocto-dev-revisions.inc
|
|
|
|
KBRANCH = "standard/base"
|
|
KMETA = "kernel-meta"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto-dev.git;branch=${KBRANCH};name=machine \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=master;destsuffix=${KMETA}"
|
|
|
|
# Set default SRCREVs. Both the machine and meta SRCREVs are statically set
|
|
# to the korg v3.7 tag, and hence prevent network access during parsing. If
|
|
# linux-yocto-dev is the preferred provider, they will be overridden to
|
|
# AUTOREV in following anonymous python routine and resolved when the
|
|
# variables are finalized.
|
|
SRCREV_machine ?= '${@oe.utils.conditional("PREFERRED_PROVIDER_virtual/kernel", "linux-yocto-dev", "${AUTOREV}", "29594404d7fe73cd80eaa4ee8c43dcc53970c60e", d)}'
|
|
SRCREV_meta ?= '${@oe.utils.conditional("PREFERRED_PROVIDER_virtual/kernel", "linux-yocto-dev", "${AUTOREV}", "29594404d7fe73cd80eaa4ee8c43dcc53970c60e", d)}'
|
|
|
|
LINUX_VERSION ?= "5.6-rc+"
|
|
LINUX_VERSION_EXTENSION ?= "-yoctodev-${LINUX_KERNEL_TYPE}"
|
|
PV = "${LINUX_VERSION}+git${SRCPV}"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
|
|
|
DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
|
|
DEPENDS += "openssl-native util-linux-native"
|
|
|
|
COMPATIBLE_MACHINE = "(qemuarm|qemux86|qemuppc|qemumips|qemumips64|qemux86-64|qemuriscv64)"
|
|
|
|
KERNEL_DEVICETREE_qemuarmv5 = "versatile-pb.dtb"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/taskstats/taskstats.scc"
|
|
KERNEL_FEATURES_append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES_append_qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
|
|
KERNEL_FEATURES_append_qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES_append_qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES_append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "" ,d)}"
|
|
|
|
KERNEL_VERSION_SANITY_SKIP = "1"
|