mirror of
https://git.yoctoproject.org/poky
synced 2026-04-30 03:32:12 +02:00
57d9840f14
mips-fix.patch removed since it's included in 1.9.12p1 Changelog: ========= *Sudo's configure script now does a better job of detecting when the -fstack-clash-protection compiler option does not work. GitHub issue #191. *Fixed CVE-2022-43995, a potential out-of-bounds write for passwords smaller than 8 characters when passwd authentication is enabled. This does not affect configurations that use other authentication methods such as PAM, AIX authentication or BSD authentication. *Fixed a build error with some configurations compiling host_port.c. (From OE-Core rev: 292acd9db1d7204f1435f31f2c37fd272b74eb97) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
63 lines
2.4 KiB
BlitzBasic
63 lines
2.4 KiB
BlitzBasic
require sudo.inc
|
|
|
|
SRC_URI = "https://www.sudo.ws/dist/sudo-${PV}.tar.gz \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '${PAM_SRC_URI}', '', d)} \
|
|
file://0001-sudo.conf.in-fix-conflict-with-multilib.patch \
|
|
file://0001-lib-util-mksigname.c-correctly-include-header-for-ou.patch \
|
|
"
|
|
|
|
PAM_SRC_URI = "file://sudo.pam"
|
|
|
|
SRC_URI[sha256sum] = "475a18a8eb3da8b2917ceab063a6baf51ea09128c3c47e3e0e33ab7497bab7d8"
|
|
|
|
DEPENDS += " virtual/crypt ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
|
|
RDEPENDS:${PN} += " ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam-plugin-limits pam-plugin-keyinit', '', d)}"
|
|
|
|
CACHED_CONFIGUREVARS = " \
|
|
ac_cv_type_rsize_t=no \
|
|
ac_cv_path_MVPROG=${base_bindir}/mv \
|
|
ac_cv_path_BSHELLPROG=${base_bindir}/sh \
|
|
ac_cv_path_SENDMAILPROG=${sbindir}/sendmail \
|
|
ac_cv_path_VIPROG=${base_bindir}/vi \
|
|
"
|
|
|
|
EXTRA_OECONF += " \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '--with-pam', '--without-pam', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--enable-tmpfiles.d=${nonarch_libdir}/tmpfiles.d', '--disable-tmpfiles.d', d)} \
|
|
--with-rundir=/run/sudo \
|
|
--with-vardir=/var/lib/sudo \
|
|
--libexecdir=${libdir} \
|
|
"
|
|
|
|
do_install:append () {
|
|
if [ "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}" ]; then
|
|
install -D -m 644 ${WORKDIR}/sudo.pam ${D}/${sysconfdir}/pam.d/sudo
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'pam-wheel', 'true', 'false', d)} ; then
|
|
echo 'auth required pam_wheel.so use_uid' >>${D}${sysconfdir}/pam.d/sudo
|
|
sed -i 's/# \(%wheel ALL=(ALL) ALL\)/\1/' ${D}${sysconfdir}/sudoers
|
|
fi
|
|
fi
|
|
|
|
chmod 4111 ${D}${bindir}/sudo
|
|
chmod 0440 ${D}${sysconfdir}/sudoers
|
|
|
|
# Explicitly remove the /sudo directory to avoid QA error
|
|
rmdir -p --ignore-fail-on-non-empty ${D}/run/sudo
|
|
}
|
|
|
|
FILES:${PN}-dev += "${libdir}/${BPN}/lib*${SOLIBSDEV} ${libdir}/${BPN}/*.la \
|
|
${libdir}/lib*${SOLIBSDEV} ${libdir}/*.la"
|
|
|
|
CONFFILES:${PN}-lib = "${sysconfdir}/sudoers"
|
|
|
|
SUDO_PACKAGES = "${PN}-sudo\
|
|
${PN}-lib"
|
|
|
|
PACKAGE_BEFORE_PN = "${SUDO_PACKAGES}"
|
|
|
|
RDEPENDS:${PN}-sudo = "${PN}-lib"
|
|
RDEPENDS:${PN} += "${SUDO_PACKAGES}"
|
|
|
|
FILES:${PN}-sudo = "${bindir}/sudo ${bindir}/sudoedit"
|
|
FILES:${PN}-lib = "${localstatedir} ${libexecdir} ${sysconfdir} ${libdir} ${nonarch_libdir}"
|