mirror of
https://git.yoctoproject.org/poky
synced 2026-05-04 13:39:49 +02:00
8fa9d64f1d
*libc's do_package will cost a lot of time due to the locale handing, which may delay the other recipe's do_package task and affect the build performance. This commit moves locale handling into a separate recipe *libc-locale. [RP: Add fixup with recent eglibc commit conflict for FILES_pn-dbg and PACKAGES] (From OE-Core rev: c6d3242f7642f537b02870bb4eb650f0e2094b85) Signed-off-by: Dongxiao Xu <dongxiao.xu@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
52 lines
2.3 KiB
PHP
52 lines
2.3 KiB
PHP
require eglibc-common.inc
|
|
|
|
STAGINGCC = "gcc-cross-intermediate"
|
|
STAGINGCC_virtclass-nativesdk = "gcc-crosssdk-intermediate"
|
|
PATH_prepend = "${STAGING_BINDIR_TOOLCHAIN}.${STAGINGCC}:"
|
|
|
|
TOOLCHAIN_OPTIONS = " --sysroot=${STAGING_DIR_TCBOOTSTRAP}"
|
|
|
|
# siteconfig.bbclass runs configure which needs a working compiler
|
|
# For the compiler to work we need a working libc yet libc isn't
|
|
# in the sysroots directory at this point. This means the libc.so
|
|
# linker script won't work as the --sysroot setting isn't correct.
|
|
# Here we create a hacked up libc linker script and pass in the right
|
|
# flags to let configure work. Ugly.
|
|
EXTRASITECONFIG = "CFLAGS='${CFLAGS} -Wl,-L${WORKDIR}/site_config_libc -L${WORKDIR}/site_config_libc -L${SYSROOT_DESTDIR}${libdir} -L${SYSROOT_DESTDIR}${base_libdir} -Wl,-L${SYSROOT_DESTDIR}${libdir} -Wl,-L${SYSROOT_DESTDIR}${base_libdir}'"
|
|
siteconfig_do_siteconfig_gencache_prepend = " \
|
|
mkdir -p ${WORKDIR}/site_config_libc; \
|
|
cp ${SYSROOT_DESTDIR}${libdir}/libc.so ${WORKDIR}/site_config_libc; \
|
|
sed -i -e 's# ${base_libdir}# ${SYSROOT_DESTDIR}${base_libdir}#g' -e 's# ${libdir}# ${SYSROOT_DESTDIR}${libdir}#g' ${WORKDIR}/site_config_libc/libc.so; \
|
|
"
|
|
|
|
# nptl needs unwind support in gcc, which can't be built without glibc.
|
|
DEPENDS = "virtual/${TARGET_PREFIX}gcc-intermediate linux-libc-headers"
|
|
#this leads to circular deps, so lets not add it yet
|
|
#RDEPENDS_ldd += " bash"
|
|
# nptl needs libgcc but dlopens it, so our shlibs code doesn't detect this
|
|
#RDEPENDS_${PN} += "${@['','libgcc']['nptl' in '${GLIBC_ADDONS}']}"
|
|
PROVIDES = "virtual/libc virtual/${TARGET_PREFIX}libc-for-gcc"
|
|
PROVIDES += "virtual/libintl virtual/libiconv"
|
|
inherit autotools
|
|
require eglibc-options.inc
|
|
|
|
LEAD_SONAME = "libc.so"
|
|
|
|
GLIBC_EXTRA_OECONF ?= ""
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
|
|
ARM_INSTRUCTION_SET = "arm"
|
|
|
|
# eglibc uses PARALLELMFLAGS variable to pass parallel build info so transfer
|
|
# PARALLEL_MAKE into PARALLELMFLAGS and empty out PARALLEL_MAKE
|
|
EGLIBCPARALLELISM := "PARALLELMFLAGS="${PARALLEL_MAKE}""
|
|
EXTRA_OEMAKE += ${EGLIBCPARALLELISM}
|
|
PARALLEL_MAKE = ""
|
|
|
|
PACKAGES = "glibc catchsegv sln nscd ldd glibc-utils glibc-dev glibc-doc libsegfault glibc-extra-nss glibc-thread-db glibc-pcprofile"
|
|
|
|
OE_FEATURES = "${@features_to_eglibc_settings(d)}"
|
|
do_configure_prepend() {
|
|
echo '${OE_FEATURES}' > ${B}/option-groups.config
|
|
}
|