packagekit: initial commit

Add both packagekit and packagekit-qt recipes.

These are dependencies for the 'discover' application. Note that I
configure packagekit in a minimalistic way as to reduce
dependencies. I wanted to have something that builds clean first.

Signed-off-by: Marc Ferland <marc.ferland@sonatest.com>

recipes-support/packagekit-qt.inc

@@ -0,0 +1,23 @@
+# SPDX-FileCopyrightText: 2024 Marc Ferland <marc.ferland@sonatest.com>
+#
+# SPDX-License-Identifier: MIT
+
+SUMMARY = "PackageKit-Qt"
+DESCRIPTION = "Qt bindings for PackageKit"
+HOMEPAGE = "https://github.com/PackageKit/PackageKit-Qt"
+LICENSE = "LGPL-2.1-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c"
+PR = "r0"
+
+DEPENDS = " \
+    qtbase \
+    packagekit \
+"
+
+RDEPENDS:${PN} += "qtbase"
+
+inherit qt6-cmake xmlcatalog
+
+EXTRA_OECMAKE += " \
+    -DBUILD_WITH_QT6=ON \
+"

recipes-support/packagekit-qt_1.1.2.bb

@@ -0,0 +1,7 @@
+# SPDX-FileCopyrightText: none
+# SPDX-License-Identifier: CC0-1.0
+
+require ${BPN}.inc
+SRC_URI = "git://github.com/PackageKit/PackageKit-Qt.git;protocol=https;branch=main"
+SRCREV = "c888e1c7be5f8a7868c7728ab18d878376fb61b8"
+S="${WORKDIR}/git"

recipes-support/packagekit.inc

@@ -0,0 +1,42 @@
+# SPDX-FileCopyrightText: 2024 Marc Ferland <marc.ferland@sonatest.com>
+#
+# SPDX-License-Identifier: MIT
+
+DESCRIPTION = "PackageKit"
+SUMMARY = "PackageKit package management abstraction"
+HOMEPAGE = "https://www.freedesktop.org/software/PackageKit/"
+LICENSE = "LGPL-2.1-or-later"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+DEPENDS = " \
+    glib-2.0 \
+    glib-2.0-native \
+    gobject-introspection-native \
+    gobject-introspection \
+    sqlite3 \
+    polkit \
+    libxslt-native \
+    docbook-xml-dtd4 \
+"
+
+EXTRA_OEMESON = " \
+    -Dgstreamer_plugin=false \
+    -Dgtk_module=false \
+    -Dbash_command_not_found=false \
+    -Dbash_completion=false \
+    -Dcron=false \
+    -Dman_pages=false \
+    -Doffline_update=false \
+    -Dpython_backend=false \
+"
+
+inherit meson pkgconfig gettext vala systemd
+
+SYSTEMD_SERVICE:${PN} = "${BPN}.service"
+SYSTEMD_AUTO_ENABLE = "disable"
+
+FILES:${PN} += " \
+    ${datadir} \
+    ${libdir}/packagekit-backend \
+    ${libdir}/girepository-1.0 \
+"

recipes-support/packagekit_1.3.0.bb

@@ -0,0 +1,7 @@
+# SPDX-FileCopyrightText: none
+# SPDX-License-Identifier: CC0-1.0
+
+require ${BPN}.inc
+SRC_URI = "https://www.freedesktop.org/software/PackageKit/releases/PackageKit-${PV}.tar.xz"
+SRC_URI[sha256sum] = "f929a9be395e94ba5b0351c3e95f09212324af12b9c30a3a6d255c443b74e0e6"
+S="${WORKDIR}/PackageKit-${PV}"