Factor out common elements from plasma recipes

classes/cmake_plasma.bbclass

@@ -0,0 +1,34 @@
+inherit cmake_qt5
+inherit gettext
+inherit python3native
+
+EXTRA_OECMAKE += " \
+    -DBUILD_TESTING=OFF \
+"
+
+DEPENDS += " \
+    extra-cmake-modules \
+    qtbase \
+"
+
+FILES_${PN} += " \
+    ${libdir}/kconf_update_bin/* \
+    ${libdir}/plugins/*.so \
+    ${libdir}/plugins/*/*.so \
+    ${libdir}/plugins/*/*/*.so \
+    ${datadir}/config.kcfg/*.kcfg \
+    ${datadir}/dbus-1/services/*.service \
+    ${datadir}/kconf_update/*.upd \
+    ${datadir}/knotifications5/*.notifyrc \
+    ${datadir}/kservices5/*.desktop \
+    ${datadir}/kservices5/*.protocol \
+    ${datadir}/kservicetypes5/*.desktop \
+    ${datadir}/polkit-1/actions/*.policy \
+"
+
+FILES_${PN}-dev += " \
+    ${datadir}/dbus-1/interfaces/*.xml \
+    ${datadir}/kdevappwizard/templates/*.tar.bz2 \
+    ${libdir}/cmake/*/*.cmake \
+    ${prefix}/mkspecs/modules/qt_*.pri \
+"

recipes-plasma/breeze.inc

@@ -5,8 +5,6 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=5c213a7de3f013310bd272cdb6eb7a24"
 PR = "r0"
 
 DEPENDS = " \
-    qtbase \
-    extra-cmake-modules \
     kcmutils \
     kconfigwidgets \
     kcoreaddons \
@@ -19,29 +17,18 @@ DEPENDS = " \
 "
 
 SRC_URI = " \
-    git://anongit.kde.org/breeze;nobranch=1 \
+    git://anongit.kde.org/${BPN};nobranch=1 \
 "
 S = "${WORKDIR}/git"
 
-inherit cmake_qt5
+inherit cmake_plasma
-inherit gettext
-inherit python3native
 
 FILES_${PN} += " \
-    ${libdir}/kconf_update_bin/* \
-    ${libdir}/plugins/*.so \
-    ${libdir}/plugins/*/*.so \
     ${libdir}/qml/QtQuick/Controls/Styles \
     ${datadir}/kstyle/themes \
-    ${datadir}/kservices5/*.desktop \
     ${datadir}/plasma/look-and-feel \
     ${datadir}/color-schemes \
     ${datadir}/icons \
-    ${datadir}/kconf_update/*.upd \
     ${datadir}/QtCurve/*.qtcurve \
     ${datadir}/wallpapers \
 "
-
-FILES_${PN}-dev += " \
-    ${libdir}/cmake/Breeze/*.cmake \
-"

recipes-plasma/kactivitymanagerd.inc

@@ -6,8 +6,6 @@ PR = "r0"
 
 DEPENDS = " \
     boost \
-    qtbase \
-    extra-cmake-modules \
     \
     kconfig \
     kcoreaddons \
@@ -20,13 +18,11 @@ DEPENDS = " \
 "
 
 SRC_URI = " \
-    git://anongit.kde.org/kactivitymanagerd;nobranch=1 \
+    git://anongit.kde.org/${BPN};nobranch=1 \
 "
 S = "${WORKDIR}/git"
 
-inherit cmake_qt5
+inherit cmake_plasma
-inherit gettext
-inherit python3native
 
 CXXFLAGS += "-DBOOST_DISABLE_ASSERTS"
 
@@ -43,9 +39,6 @@ EXTRA_OECMAKE += " \
 
 FILES_${PN} += " \
     ${libdir}/*.so \
-    ${libdir}/plugins/kactivitymanagerd/1/*.so \
-    ${datadir}/kservices5/*.desktop \
-    ${datadir}/kservicetypes5/*.desktop \
 "
 
 FILES_${PN}-dev = ""

recipes-plasma/kdecoration.inc

@@ -4,18 +4,9 @@ LICENSE = "LGPLv2.1"
 LIC_FILES_CHKSUM = "file://COPYING.LIB;md5=2d5025d4aa3495befef8f17206a5b0a1"
 PR = "r0"
 
-DEPENDS = " \
-    qtbase \
-    extra-cmake-modules \
-"
-
 SRC_URI = " \
-    git://anongit.kde.org/${PN};nobranch=1 \
+    git://anongit.kde.org/${BPN};nobranch=1 \
 "
 S = "${WORKDIR}/git"
 
-inherit cmake_qt5
+inherit cmake_plasma
-
-FILES_${PN}-dev += " \
-    ${libdir}/cmake/KDecoration2/*.cmake \
-"

recipes-plasma/kscreenlocker.inc

@@ -5,9 +5,7 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
 PR = "r0"
 
 DEPENDS = " \
-    qtbase \
     qtdeclarative \
-    extra-cmake-modules \
     kwayland \
     kcrash \
     kdeclarative \
@@ -26,12 +24,12 @@ DEPENDS = " \
 "
 
 SRC_URI = " \
-    git://git.kde.org/${PN};nobranch=1 \
+    git://git.kde.org/${BPN};nobranch=1 \
 "
 S = "${WORKDIR}/git"
 
 
-inherit cmake_qt5 gettext python3native
+inherit cmake_plasma
 
 do_compile_prepend() {
     # desktoptojson needs to find installed service type files
@@ -39,17 +37,7 @@ do_compile_prepend() {
 }
 
 FILES_${PN} += " \
-  ${datadir}/kconf_update/* \
-  ${datadir}/knotifications5/*.notifyrc \
-  ${datadir}/kservices5/*.desktop \
   ${datadir}/ksmserver/screenlocker/org.kde.passworddialog/*.desktop \
-  ${libdir}/plugins/*.so \
-"
-
-FILES_${PN}-dev += " \
-    ${datadir}/dbus-1/interfaces/*.xml \
-    ${libdir}/cmake/KScreenLocker/*.cmake \
-    ${libdir}/cmake/ScreenSaverDBusInterface/*.cmake \
 "
 
 RDEPENDS_${PN} += "perl"

recipes-plasma/kwayland-integration.inc

@@ -5,8 +5,6 @@ LIC_FILES_CHKSUM = "file://COPYING.LIB;md5=2d5025d4aa3495befef8f17206a5b0a1"
 PR = "r0"
 
 DEPENDS = " \
-    qtbase \
-    extra-cmake-modules \
     kidletime \
     kwindowsystem \
     kwayland \
@@ -17,9 +15,4 @@ SRC_URI = " \
 "
 S = "${WORKDIR}/git"
 
-inherit cmake_qt5
+inherit cmake_plasma
-
-FILES_${PN} += " \
-    ${libdir}/plugins/kf5/org.kde.kwindowsystem.platforms/*.so \
-    ${libdir}/plugins/kf5/org.kde.kidletime.platforms/*.so \
-"

recipes-plasma/kwin.inc

@@ -5,9 +5,7 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=5c213a7de3f013310bd272cdb6eb7a24"
 PR = "r0"
 
 DEPENDS = " \
-    qtbase \
     qtdeclarative \
-    extra-cmake-modules \
     kconfigwidgets \
     kcrash \
     kglobalaccel \
@@ -47,7 +45,7 @@ SRC_URI_append_raspberrypi += " \
 
 S = "${WORKDIR}/git"
 
-inherit cmake_qt5 gettext python3native
+inherit cmake_plasma
 
 do_compile_prepend() {
     # desktoptojson needs to find installed service type files

recipes-plasma/libkscreen.inc

@@ -5,27 +5,13 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
 PR = "r0"
 
 DEPENDS = " \
-    qtbase \
     qtx11extras \
-    extra-cmake-modules \
     kwayland \
 "
 
 SRC_URI = " \
-    git://anongit.kde.org/libkscreen;nobranch=1 \
+    git://anongit.kde.org/${BPN};nobranch=1 \
 "
 S = "${WORKDIR}/git"
 
-inherit cmake_qt5
+inherit cmake_plasma
-inherit gettext
-inherit python3native
-
-FILES_${PN} += " \
-    ${libdir}/plugins/kf5/kscreen/*.so \
-    ${datadir}/dbus-1/services/*.service \
-"
-
-FILES_${PN}-dev += " \
-    ${libdir}/cmake/KF5Screen/*.cmake \
-    ${prefix}/mkspecs/modules/qt_*.pri \
-"

recipes-plasma/libksysguard.inc

@@ -5,8 +5,6 @@ LIC_FILES_CHKSUM = "file://COPYING.LIB;md5=2d5025d4aa3495befef8f17206a5b0a1"
 PR = "r0"
 
 DEPENDS = " \
-    qtbase \
-    extra-cmake-modules \
     kcoreaddons \
     kconfig \
     ki18n \
@@ -20,21 +18,13 @@ DEPENDS = " \
 "
 
 SRC_URI = " \
-    git://anongit.kde.org/libksysguard;nobranch=1 \
+    git://anongit.kde.org/${BPN};nobranch=1 \
 "
 S = "${WORKDIR}/git"
 
-inherit cmake_qt5
+inherit cmake_plasma
-inherit gettext
-inherit python3native
 
 FILES_${PN} += " \
     ${datadir}/ksysguard/scripts/* \
     ${datadir}/ksysguard/scripts/*/* \
-    ${datadir}/dbus-1/system-services/*.service \
-    ${datadir}/polkit-1/actions/*.policy \
-"
-
-FILES_${PN}-dev += " \
-    ${libdir}/cmake/KF5SysGuard/*.cmake \
 "

recipes-plasma/plasma-integration.inc

@@ -5,10 +5,8 @@ LIC_FILES_CHKSUM = "file://COPYING.LGPL-3;md5=e6a600fd5e1d9cbde2d983680233ad02"
 PR = "r0"
 
 DEPENDS = " \
-    qtbase \
     qtx11extras \
     qtquickcontrols2 \
-    extra-cmake-modules \
     kconfig \
     kconfigwidgets \
     ki18n \
@@ -23,17 +21,10 @@ DEPENDS = " \
 "
 
 SRC_URI = " \
-    git://anongit.kde.org/plasma-integration;nobranch=1 \
+    git://anongit.kde.org/${BPN};nobranch=1 \
 "
 S = "${WORKDIR}/git"
 
-inherit cmake_qt5
+inherit cmake_plasma
-inherit gettext
-inherit python3native
-
-FILES_${PN} += " \
-    ${libdir}/plugins/platformthemes/KDEPlasmaPlatformTheme.so \
-    ${datadir}/kconf_update/* \
-"
 
 RDEPENDS_${PN} += "perl"

recipes-plasma/plasma-phone-components.inc

@@ -6,7 +6,6 @@ LIC_FILES_CHKSUM = "file://README.md;md5=4b29ea33c047d21253e6e3718dc59f7c"
 PR = "r0"
 
 DEPENDS = " \
-    qtbase \
     telepathy-qt \
     kwayland \
     plasma-framework \
@@ -14,24 +13,20 @@ DEPENDS = " \
 "
 
 SRC_URI = " \
-    git://anongit.kde.org/${PN};nobranch=1 \
+    git://anongit.kde.org/${BPN};nobranch=1 \
 "
 S = "${WORKDIR}/git"
 
-inherit cmake_qt5 gettext python3native
+inherit cmake_plasma
 
 FILES_${PN} += " \
-    ${libdir}/plugins/plasma/applets/*.so \
     ${libdir}/qml/QtQuick/VirtualKeyboard/Styles/Plasma/* \
     ${libdir}/qml/org/kde/plasma/private/mobileshell/* \
     ${libdir}/qml/org/kde/plasma/private/kpeoplehelper/* \
     ${datadir}/kpackage/genericqml/org.kde.phone.dialer/* \
-    ${datadir}/knotifications5/*.notifyrc \
-    ${datadir}/kservices5/*.desktop \
     ${datadir}/plasma/shells/org.kde.plasma.phone/* \
     ${datadir}/plasma/plasmoids/* \
     ${datadir}/plasma/look-and-feel/org.kde.plasma.phone/* \
-    ${datadir}/dbus-1/services/*.service \
     ${datadir}/telepathy/clients/Plasma.Dialer.client \
     ${datadir}/kwin/scripts/org.kde.phone.multitasking/* \
     ${datadir}/wallpapers/org.kde.plasma.phone.lockers/* \

recipes-plasma/plasma-workspace.inc

@@ -5,10 +5,8 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=5c213a7de3f013310bd272cdb6eb7a24"
 PR = "r0"
 
 DEPENDS = " \
-    qtbase \
     qtdeclarative \
     baloo \
-    extra-cmake-modules \
     karchive-native \
     kcoreaddons \
     kcrash \
@@ -45,7 +43,7 @@ SRC_URI = " \
 "
 S = "${WORKDIR}/git"
 
-inherit cmake_qt5 gettext python3native
+inherit cmake_plasma
 
 EXTRA_OECMAKE += " -DBUILD_xembed-sni-proxy=OFF"
 
@@ -58,21 +56,9 @@ do_compile_prepend() {
 
 FILES_${PN} += " \
     ${libdir}/libkdeinit5_*.so \
-    ${libdir}/kconf_update_bin/krunnerplugins \
-    ${libdir}/plugins/*.so \
-    ${libdir}/plugins/kpackage/packagestructure/*.so \
-    ${libdir}/plugins/plasma/applets/*.so \
-    ${libdir}/plugins/plasma/dataengine/*.so \
-    ${libdir}/plugins/plasma/packagestructure/*.so \
-    ${libdir}/plugins/phonon_platform/kde.so \
-    ${libdir}/plugins/kf5/kio/*.so \
-    ${libdir}/plugins/kf5/kded/*.so \
     ${libdir}/qml/org/kde/taskmanager/* \
     ${libdir}/qml/org/kde/plasma \
-    ${datadir}/knotifications5/*.notifyrc \
     ${datadir}/kstyle/themes/*.themerc \
-    ${datadir}/kservices5/*.desktop \
-    ${datadir}/kservices5/*.protocol \
     ${datadir}/ksmserver/themes \
     ${datadir}/ksplash/Themes \
     ${datadir}/kservicetypes5/*.desktop \
@@ -83,13 +69,10 @@ FILES_${PN} += " \
     ${datadir}/plasma/wallpapers \
     ${datadir}/plasma/services/*.operations \
     ${datadir}/solid/actions/*.desktop \
-    ${datadir}/dbus-1/services/*.service \
     ${datadir}/sddm/themes \
     ${datadir}/desktop-directories/*.directory \
     ${datadir}/wayland-sessions/*.desktop \
-    ${datadir}/kconf_update/*.upd \
     ${datadir}/xsessions/*.desktop \
-    ${datadir}/config.kcfg/*.kcfg \
 "
 
 FILES_${PN}-dev = " \