From 95964b0fd814f02b2f1f8a82d29031bf3b5e66f9 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Andreas=20M=C3=BCller?= <schnitzeltony@gmail.com>
Date: Sat, 19 Dec 2020 15:22:25 +0100
Subject: [PATCH] musescore: initial add 3.5.2
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
---
 recipes-musicians/musescore/musescore.bb      | 74 +++++++++++++++++++
 .../packagegroups/musicians-world.bb          |  1 +
 2 files changed, 75 insertions(+)
 create mode 100644 recipes-musicians/musescore/musescore.bb

diff --git a/recipes-musicians/musescore/musescore.bb b/recipes-musicians/musescore/musescore.bb
new file mode 100644
index 0000000..d92deae
--- /dev/null
+++ b/recipes-musicians/musescore/musescore.bb
@@ -0,0 +1,74 @@
+SUMMARY = "MuseScore is an open source and free music notation software"
+HOMEPAGE = "https://musescore.org"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://LICENSE.GPL;md5=ef318be74ef69ee7f919c9ebb45b6e21"
+
+python() {
+    if 'clang-layer' not in d.getVar('BBFILE_COLLECTIONS').split():
+        raise bb.parse.SkipRecipe('Requires meta-clang to be present due to qthelp requiring clang.')
+}
+
+DEPENDS = " \
+    qttools-native \
+    qttools \
+    gzip-native \
+    qtbase \
+    qtdeclarative \
+    qtsvg \
+    qtwebengine \
+    freetype \
+    libsndfile1 \
+    lame \
+    fluidsynth \
+    portaudio-v19 \
+    portmidi \
+    poppler \
+    freetype \
+"
+
+SRC_URI = "git://github.com/musescore/MuseScore.git;branch=${PV}"
+SRCREV = "465e7b6fe50973a24a75891e27575a8d2b962f6a"
+S = "${WORKDIR}/git"
+PV = "3.5.2"
+
+inherit qmake5_base cmake_qt5 pkgconfig gtk-icon-cache mime mime-xdg features_check
+
+OECMAKE_GENERATOR = "Unix Makefiles"
+
+PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'pulseaudio', d)}"
+PACKAGECONFIG[pulseaudio] = "-DBUILD_PULSEAUDIO=ON,-DBUILD_PULSEAUDIO=OFF,pulseaudio,pulseaudio-server"
+
+EXTRA_OECMAKE = " \
+    -DMUSESCORE_BUILD_CONFIG=release \
+    -DBUILD_TELEMETRY_MODULE=OFF \
+    -DBUILD_PCH=OFF \
+    -DDOWNLOAD_SOUNDFONT=OFF \
+    -DUSE_SYSTEM_FREETYPE=ON \
+    -DUSE_SYSTEM_POPPLER=ON \
+    -DCMAKE_SKIP_RPATH=TRUE \
+"
+
+# musescore's cmake uses qmake => we need a qt.conf and some hacks
+OE_QMAKE_QMAKE = "echo"
+QMAKE_PROFILES = "dummy.pro"
+
+do_configure() {
+    sed -i 's:${QT_QMAKE_EXECUTABLE} \"-query\":${QT_QMAKE_EXECUTABLE} \"-query\" \"-qtconf ${WORKDIR}/qt.conf\"':g ${S}/build/FindQt5.cmake
+    qmake5_base_do_configure
+    cmake_do_configure
+    # cmake's find_library has never played nicely for us
+    sed -i 's: ${libdir}/libpulse.so: ${STAGING_LIBDIR}/libpulse.so:g' ${B}/main/CMakeFiles/mscore.dir/build.make
+}
+
+do_install_append() {
+    # they copy QtWebEngineProcess from libexe to bindir - tse tse
+    rm -f ${D}${bindir}/QtWebEngineProcess
+}
+
+FILES_${PN} += " \
+    ${datadir}/mscore-3.5 \
+    ${datadir}/metainfo \
+    ${datadir}/mime \
+    ${libdir}/qt5 \
+"
+
diff --git a/recipes-support/packagegroups/musicians-world.bb b/recipes-support/packagegroups/musicians-world.bb
index 80090fb..6d4af90 100644
--- a/recipes-support/packagegroups/musicians-world.bb
+++ b/recipes-support/packagegroups/musicians-world.bb
@@ -101,6 +101,7 @@ RDEPENDS_${PN} += " \
     \
     mixxx \
     muse \
+    ${@bb.utils.contains('BBFILE_COLLECTIONS', 'clang-layer', 'musescore', '', d)} \
     nekobee \
     ninjas2-standalone ninjas2-lv2 ninjas2-vst \
     noise-repellent \