lumina-pdf: initial 1.5.0

It was split out of lumina repo

Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>

recipes-lumina/lumina-desktop/lumina-pdf.bb

@@ -0,0 +1,46 @@
+SUMMARY = "PDF Viewer Utility from the Lumina Desktop"
+HOMEPAGE = "https://lumina-desktop.org/"
+LICENSE = "BSD-2-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=45b10a7bfb52b622b91ca67ea02e4afa"
+
+REQUIRED_DISTRO_FEATURES = "x11"
+
+QT_TRANSLATION_FILES = "${datadir}/*/i18n/*.qm"
+
+inherit qmake5 distro_features_check gtk-icon-cache qt5-translation manpages
+
+DEPENDS += " \
+    qttools-native \
+    qtbase \
+    poppler \
+"
+
+SRC_URI = " \
+    git://github.com/lumina-desktop/lumina-pdf.git \
+    file://0001-drawablepage.h-Add-missing-include.patch \
+"
+SRCREV = "645ed591ef91c3607d3ab87dd86f7acfd08b05c9"
+S = "${WORKDIR}/git/src-qt5"
+PV = "1.5.0"
+
+do_configure_prepend() {
+    # change paths by sed instead of endles escapes in 'DEFINES+=..' below
+    sed -i 's:L_ETCDIR:QString("${sysconfdir}"):' `find ${S} -name *.cpp`
+    sed -i 's:L_SHAREDIR:QString("${datadir}"):' `find ${S} -name *.cpp`
+    sed -i 's:$${MAN_ZIP}:gzip -c:' `find ${S} -name *.pro`
+}
+
+# Override magic in src-qt5/OS-detect.pri to our paths
+EXTRA_QMAKEVARS_PRE += ' \
+    OS=Linux \
+    PREFIX=${prefix} \
+    L_BINDIR=${bindir} \
+    L_LIBDIR=${libdir} \
+    L_ETCDIR=${sysconfdir} \
+    L_SHAREDIR=${datadir} \
+    L_INCLUDEDIR=${STAGING_INCDIR} \
+    L_SESSDIR=${datadir}/xsessions \
+    L_MANDIR=${mandir} \
+    LRELEASE=${OE_QMAKE_PATH_EXTERNAL_HOST_BINS}/lrelease \
+    CONFIG+=WITH_I18N \
+'

recipes-lumina/lumina-desktop/lumina-pdf/0001-drawablepage.h-Add-missing-include.patch

@@ -0,0 +1,40 @@
+From 61d568c309de582d917692b399778ea892290645 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Andreas=20M=C3=BCller?= <schnitzeltony@gmail.com>
+Date: Mon, 29 Apr 2019 21:08:29 +0200
+Subject: [PATCH] drawablepage.h: Add missing include
+MIME-Version: 1.0
+Content-Type: text/plain; charset=UTF-8
+Content-Transfer-Encoding: 8bit
+
+| In file included from ../git/src-qt5/Renderer-poppler.cpp:2:
+| ../git/src-qt5/drawablepage.h:34:8: error: 'unique_ptr' in namespace 'std' does not name a template type
+|    std::unique_ptr<Poppler::Page> page;
+|         ^~~~~~~~~~
+| ../git/src-qt5/drawablepage.h:34:3: note: 'std::unique_ptr' is defined in header '<memory>'; did you forget to '#include <memory>'?
+| ../git/src-qt5/drawablepage.h:7:1:
+| +#include <memory>
+
+Upstream-Status: Submitted [1]
+
+[1] https://github.com/lumina-desktop/lumina-pdf/pull/1
+
+Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
+---
+ drawablepage.h | 1 +
+ 1 file changed, 1 insertion(+)
+
+diff --git a/drawablepage.h b/drawablepage.h
+index ee3b76e..4e8d9c2 100644
+--- a/drawablepage.h
++++ b/drawablepage.h
+@@ -4,6 +4,7 @@
+ #include <QImage>
+ #include <QSize>
+ #include <poppler/qt5/poppler-qt5.h>
++#include <memory>
+ 
+ namespace LuminaPDF {
+ 
+-- 
+2.20.1
+