From eec93316d3ff08f2c19465bb8420976173d659b3 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Andreas=20M=C3=BCller?= <schnitzeltony@gmail.com>
Date: Sun, 31 Dec 2017 10:20:50 +0100
Subject: [PATCH] nekobi: initial add
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
---
 .../recipes-multimedia/distrho/nekobi.bb      | 56 +++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 recipes-misc/recipes-multimedia/distrho/nekobi.bb

diff --git a/recipes-misc/recipes-multimedia/distrho/nekobi.bb b/recipes-misc/recipes-multimedia/distrho/nekobi.bb
new file mode 100644
index 00000000..bde53a1f
--- /dev/null
+++ b/recipes-misc/recipes-multimedia/distrho/nekobi.bb
@@ -0,0 +1,56 @@
+SUMMARY = "Single-oscillator synth based on the Roland TB-303"
+HOMEPAGE = "http://distrho.sourceforge.net/ports"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = " \
+    file://LICENSE;md5=4641e94ec96f98fabc56ff9cc48be14b \
+"
+
+SRC_URI = " \
+    gitsm://github.com/DISTRHO/Nekobi.git \
+"
+
+SRCREV = "9e51059f8badedfab41971498680e229cccdb456"
+S = "${WORKDIR}/git"
+PV = "0.0.0+git${SRCPV}"
+
+inherit qemu-ext pkgconfig
+
+CLEANBROKEN = "1"
+
+do_configure_prepend() {
+	# manipulate scripts to keep lv2_ttl_generator-calls in script for qemu
+    sed -i 's|$GEN ./$FILE|echo `pwd`/$FILE >> ${WORKDIR}/lv2_ttl_generator-data|g' `find ${S} -name *.sh`
+}
+
+EXTRA_OEMAKE += " \
+    NOOPT=true \
+"
+
+do_compile_append() {
+    # build ttl-files must be done in quemu
+    for sofile in `cat ${WORKDIR}/lv2_ttl_generator-data`; do
+        cd `dirname ${sofile}`
+        echo "QEMU lv2_ttl_generator for ${sofile}..."
+        ${@qemu_run_binary_local(d, '${STAGING_DIR_TARGET}', '${S}/libs/lv2_ttl_generator')} ${sofile} || echo "ERROR: for QEMU lv2_ttl_generator for ${sofile}!"
+    done
+}
+
+do_install() {
+    install -d ${D}${libdir}/dssi
+	install -m 0644 ${S}/bin/Nekobi-dssi.so ${D}${libdir}/dssi/
+
+    install -d ${D}${libdir}/vst
+	install -m 0644 ${S}/bin/Nekobi-vst.so ${D}${libdir}/vst/
+
+    install -d ${D}${libdir}/lv2
+	cp -r ${S}/bin/Nekobi.lv2 ${D}${libdir}/lv2/
+}
+
+FILES_${PN} += " \
+    ${libdir}/dssi \
+    ${libdir}/lv2 \
+    ${libdir}/vst \
+"
+
+# Have not found what causes stripping - debugging of plugins is unlikely
+INSANE_SKIP_${PN} = "already-stripped"