diff --git a/recipes-browser/midori/midori/0001-Do-no-search-for-cross-g-ir-compiler-but-g-ir-compil.patch b/recipes-browser/midori/midori/0001-Do-no-search-for-cross-g-ir-compiler-but-g-ir-compil.patch
new file mode 100644
index 0000000..d82a1f5
--- /dev/null
+++ b/recipes-browser/midori/midori/0001-Do-no-search-for-cross-g-ir-compiler-but-g-ir-compil.patch
@@ -0,0 +1,32 @@
+From ccf4abdd7b2e521e0665186e620a606277682597 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Andreas=20M=C3=BCller?= <schnitzeltony@gmail.com>
+Date: Tue, 18 Feb 2020 00:07:24 +0100
+Subject: [PATCH] Do no search for cross g-ir-compiler but
+ g-ir-compiler-wrapper
+MIME-Version: 1.0
+Content-Type: text/plain; charset=UTF-8
+Content-Transfer-Encoding: 8bit
+
+Upstream-Status: Inappropriate [embedded specific]
+
+Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
+---
+ core/CMakeLists.txt | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/core/CMakeLists.txt b/core/CMakeLists.txt
+index c4982de9..80fdd309 100644
+--- a/core/CMakeLists.txt
++++ b/core/CMakeLists.txt
+@@ -66,7 +66,7 @@ set_target_properties("${LIBCORE}" PROPERTIES
+                       VERSION ${LIBCORE_VERSION}
+                       )
+ 
+-find_program (GIR_COMPILER_BIN g-ir-compiler)
++find_program (GIR_COMPILER_BIN g-ir-compiler-wrapper)
+ add_custom_target(${LIBCORE_GIR}.typelib ALL
+                   COMMAND ${GIR_COMPILER_BIN} ${CMAKE_CURRENT_BINARY_DIR}/${LIBCORE_GIR}.gir
+                   --output ${CMAKE_CURRENT_BINARY_DIR}/${LIBCORE_GIR}.typelib
+-- 
+2.21.0
+
diff --git a/recipes-browser/midori/midori_git.bb b/recipes-browser/midori/midori_git.bb
new file mode 100644
index 0000000..7b3d937
--- /dev/null
+++ b/recipes-browser/midori/midori_git.bb
@@ -0,0 +1,61 @@
+SUMMARY = "A lightweight web browser"
+HOMEPAGE = "https://www.midori-browser.org/"
+LICENSE = "LGPLv2.1"
+LIC_FILES_CHKSUM = "file://COPYING;md5=fbc093901857fcd118f065f900982c24"
+
+DEPENDS = " \
+    intltool-native \
+    gcr \
+    webkitgtk \
+    json-glib \
+    libarchive \
+    libsoup-2.4 \
+    libpeas \
+    sqlite \
+"
+
+inherit cmake pkgconfig gtk-icon-cache gettext vala python3native features_check gobject-introspection mime-xdg
+
+ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
+
+# Midori requires gobject-introspection to build. Check below is not the whole
+# story: There are some extra machine-specific disable entries in webkitgtk
+# recipe and there is nothing we can do to check here...
+python () {
+    if d.getVar('GI_DATA_ENABLED') != 'True':
+        raise bb.parse.SkipRecipe('Midori needs gobject-introspection but it is either disabled or machine does not support it!' )
+}
+
+SRC_URI = " \
+    git://github.com/midori-browser/core.git \
+    file://0001-Do-no-search-for-cross-g-ir-compiler-but-g-ir-compil.patch \
+"
+SRCREV = "f6b3b1e030db7eb2de7faf73ec4ccc18949b668d"
+PV = "9.0"
+S = "${WORKDIR}/git"
+
+EXTRA_OECMAKE = " \
+    -DCMAKE_INSTALL_PREFIX=${prefix} \
+    -DCMAKE_INSTALL_SYSCONFDIR=/etc \
+"
+
+do_configure_prepend() {
+    export VALAC=${STAGING_BINDIR_NATIVE}/valac
+}
+
+RRECOMMENDS_${PN} += " \
+    glib-networking ca-certificates \
+    adwaita-icon-theme \
+"
+
+# No project but oe packs gstreamer plugins that fine as we do. Cannot say
+# which plugins are # really necessary so use gstreamer1.0-plugins-*-meta.
+# These are necessary to make video streaming work - see [1]
+# [1] https://github.com/midori-browser/core/issues/329
+RRECOMMENDS_${PN} += " \
+    gstreamer1.0-plugins-base-meta \
+    gstreamer1.0-plugins-good-meta \
+    gstreamer1.0-libav \
+"
+
+FILES_${PN} += "${datadir}/metainfo"