samplv1: upgrade 0.9.6 -> 0.9.7 / move PV into recipe

Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>

recipes-musicians/rncbc/samplv1.bb

@@ -0,0 +1,39 @@
+SUMMARY = "An old-school polyphonic sampler"
+HOMEPAGE = "http://samplv1.sourceforge.net"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
+
+DEPENDS += " \
+    qtbase-native \
+    qtbase \
+    jack \
+    lv2 \
+    liblo \
+"
+
+inherit qmake5_base autotools-brokensep pkgconfig gtk-icon-cache mime
+
+SRC_URI = " \
+    ${SOURCEFORGE_MIRROR}/project/${BPN}/${BPN}/${PV}/${BPN}-${PV}.tar.gz \
+    file://0001-no-Qt4-find-native-qt-build-tools-by-configure-options-auto.patch \
+    file://0002-Remove-extra-rpath.patch \
+"
+PV = "0.9.7"
+SRC_URI[md5sum] = "ed85e8afe5fc4f56ac828bfbf04a8397"
+SRC_URI[sha256sum] = "30d91669cad9074aac405d36df55173720786d48d53cc76ba518bfcb9864f5ed"
+
+EXTRA_OECONF = " \
+    --with-qmake=${OE_QMAKE_PATH_EXTERNAL_HOST_BINS}/qmake \
+    --with-moc=${OE_QMAKE_PATH_EXTERNAL_HOST_BINS}/moc \
+    --with-uic=${OE_QMAKE_PATH_EXTERNAL_HOST_BINS}/uic \
+    --with-lupdate=${OE_QMAKE_PATH_EXTERNAL_HOST_BINS}/lupdate \
+    --with-lrelease=${OE_QMAKE_PATH_EXTERNAL_HOST_BINS}/lrelease \
+"
+
+FILES_${PN} += " \
+    ${datadir}/appdata \
+    ${datadir}/mime \
+    ${datadir}/metainfo \
+    ${datadir}/icons \
+    ${libdir}/lv2 \
+"