mirror of
https://github.com/schnitzeltony/meta-musicians.git
synced 2026-01-29 17:18:41 +01:00
b4933eef7f
Took me a while to understand whats's going on: master was rebased [1-2] which causes github release revisions point to thin air. New revision was found by commit message. [1] https://github.com/davy7125/polyphone/issues/60 [2] https://github.com/davy7125/polyphone/issues/55 Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
55 lines
1.3 KiB
BlitzBasic
55 lines
1.3 KiB
BlitzBasic
SUMMARY = "Soundfont editor"
|
|
HOMEPAGE = "http://polyphone-soundfonts.com/en/"
|
|
LICENSE = "GPLv3"
|
|
LIC_FILES_CHKSUM = "file://main.cpp;beginline=6;endline=18;md5=11e8b245e7c8a15dafd52bc856ef3ff1"
|
|
|
|
inherit qmake5 gtk-icon-cache mime
|
|
|
|
DEPENDS += " \
|
|
qtbase \
|
|
qtsvg \
|
|
alsa-lib \
|
|
jack \
|
|
portaudio-v19 \
|
|
rtmidi \
|
|
qcustomplot \
|
|
stk \
|
|
libvorbis \
|
|
libogg \
|
|
"
|
|
|
|
SRC_URI = " \
|
|
git://github.com/davy7125/polyphone.git \
|
|
file://polyphone.desktop \
|
|
file://polyphone.mime \
|
|
file://0001-align-compiler-switches-constants-for-cross-compilin.patch \
|
|
"
|
|
SRCREV = "e5863e3147599e51563cd93d5f1e4f96384eba9b"
|
|
S = "${WORKDIR}/git/sources"
|
|
|
|
do_configure_prepend() {
|
|
sed -i \
|
|
-e 's:= /usr/include:= ${STAGING_INCDIR}:g' \
|
|
-e 's:^DEFINES += USE_LOCAL_:#DEFINES += USE_LOCAL_:g' \
|
|
${S}/polyphone.pro
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${bindir}
|
|
install -m 0755 ${B}/bin/polyphone ${D}${bindir}/
|
|
|
|
install -d ${D}${datadir}/pixmaps
|
|
install -m 0644 ${S}/resources/polyphone.png ${D}${datadir}/pixmaps/
|
|
|
|
install -d ${D}${datadir}/applications
|
|
install -m 0644 ${WORKDIR}/${BPN}.desktop ${D}${datadir}/applications/
|
|
|
|
install -d ${D}${datadir}/mime/packages
|
|
install -m 0644 ${WORKDIR}/${BPN}.mime ${D}${datadir}/mime/packages/${BPN}.xml
|
|
}
|
|
|
|
FILES_${PN} += " \
|
|
${datadir}/mime \
|
|
"
|
|
|