qemu-nios2: New MACHINE

Added support for Zephyr qemu-nios2 BOARD.
Nios2 CPU is not supported natively by upstream QEMU,
so a Nios2 specific patch needs to be applied.

[YOCTO#10660]

Signed-off-by: Juro Bystricky <juro.bystricky@intel.com>

conf/machine/include/tune-nios2.inc

@@ -0,0 +1,19 @@
+
+# Nios2 Architecture Definition
+
+DEFAULTTUNE ?= "nios2"
+
+TUNE_ARCH = "nios2"
+TUNE_PKGARCH = "nios2"
+TUNE_FEATURES_tune-nios2 = "nios2"
+TUNE_CCARGS = ""
+
+TUNEVALID[nios2] = "Altera Nios2"
+
+def nios2_machdata_setfunc(machdata, d):
+    machdata["elf"] = {"nios2":  (113, 0, 0, True, 32), }
+    return machdata
+
+PACKAGEQA_EXTRA_MACHDEFFUNCS = "nios2_machdata_setfunc"
+
+PACKAGE_EXTRA_ARCHS_tune-nios2 = "nios2"

conf/machine/qemu-nios2.conf

@@ -0,0 +1,11 @@
+#@TYPE: Machine
+#@NAME: qemu-nios2
+#@DESCRIPTION: Machine for Zephyr BOARD qemu_nios2
+
+require conf/machine/include/qemu.inc
+require conf/machine/include/tune-nios2.inc
+
+# For runqemu (TBD)
+QB_SYSTEM_NAME = "qemu-system-nios2"
+QB_MACHINE = "-machine altera_10m50_zephyr"
+QB_OPT_APPEND = "-nographic -cpu=nios2"

recipes-devtools/qemu/qemu_2.7.%.bbappend

@@ -0,0 +1,12 @@
+FILESEXTRAPATHS_prepend := "${THISDIR}/files:"
+
+QEMU_TARGETS = ""
+
+SRC_URI += " \
+      file://nios2-add-support.patch \
+      "
+
+EXTRA_OECONF_remove = "--target-list"
+
+QEMUS_BUILT = "arm-softmmu i386-softmmu nios2-softmmu"
+EXTRA_OECONF_append = " --target-list="${QEMUS_BUILT}""