mirror of
https://git.yoctoproject.org/poky
synced 2026-04-18 03:32:13 +02:00
linux-yocto: introduce v5.10 reference kernel recipes
The 5.10 kernel will replace 5.8 as the reference kernel for the next release. With this commit, we add standard/tiny/rt support for that kernel across all of the supported architectures and qemu reference machines. (From OE-Core rev: 74c5b98979172c0057883568df453da019abe235) Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
This commit is contained in:
Bruce Ashfield
committed by
Richard Purdie
Richard Purdie
parent
e400686558
commit
5093ecb7ff
44
meta/recipes-kernel/linux/linux-yocto-rt_5.10.bb
Normal file
44
meta/recipes-kernel/linux/linux-yocto-rt_5.10.bb
Normal file
@@ -0,0 +1,44 @@
|
||||
KBRANCH ?= "v5.10/standard/preempt-rt/base"
|
||||
|
||||
require recipes-kernel/linux/linux-yocto.inc
|
||||
|
||||
# Skip processing of this recipe if it is not explicitly specified as the
|
||||
# PREFERRED_PROVIDER for virtual/kernel. This avoids errors when trying
|
||||
# to build multiple virtual/kernel providers, e.g. as dependency of
|
||||
# core-image-rt-sdk, core-image-rt.
|
||||
python () {
|
||||
if d.getVar("KERNEL_PACKAGE_NAME") == "kernel" and d.getVar("PREFERRED_PROVIDER_virtual/kernel") != "linux-yocto-rt":
|
||||
raise bb.parse.SkipRecipe("Set PREFERRED_PROVIDER_virtual/kernel to linux-yocto-rt to enable it")
|
||||
}
|
||||
|
||||
SRCREV_machine ?= "b0c1a1f057968d659a016b919bd834ff13e26c80"
|
||||
SRCREV_meta ?= "1c2727e4bf30f06e6135ef59999b53cf465f6371"
|
||||
|
||||
SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;branch=${KBRANCH};name=machine \
|
||||
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.10;destsuffix=${KMETA}"
|
||||
|
||||
LINUX_VERSION ?= "5.10.1"
|
||||
|
||||
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
||||
|
||||
DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
|
||||
DEPENDS += "openssl-native util-linux-native"
|
||||
|
||||
PV = "${LINUX_VERSION}+git${SRCPV}"
|
||||
|
||||
KMETA = "kernel-meta"
|
||||
KCONF_BSP_AUDIT_LEVEL = "1"
|
||||
|
||||
LINUX_KERNEL_TYPE = "preempt-rt"
|
||||
|
||||
COMPATIBLE_MACHINE = "(qemux86|qemux86-64|qemuarm|qemuarmv5|qemuarm64|qemuppc|qemumips)"
|
||||
|
||||
KERNEL_DEVICETREE_qemuarmv5 = "versatile-pb.dtb"
|
||||
|
||||
# Functionality flags
|
||||
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/taskstats/taskstats.scc"
|
||||
KERNEL_FEATURES_append = " ${KERNEL_EXTRA_FEATURES}"
|
||||
KERNEL_FEATURES_append_qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
|
||||
KERNEL_FEATURES_append_qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
||||
KERNEL_FEATURES_append_qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
||||
KERNEL_FEATURES_append = "${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
|
||||
32
meta/recipes-kernel/linux/linux-yocto-tiny_5.10.bb
Normal file
32
meta/recipes-kernel/linux/linux-yocto-tiny_5.10.bb
Normal file
@@ -0,0 +1,32 @@
|
||||
KBRANCH ?= "v5.10/standard/tiny/base"
|
||||
KBRANCH_qemuarm ?= "v5.10/standard/tiny/arm-versatile-926ejs"
|
||||
|
||||
LINUX_KERNEL_TYPE = "tiny"
|
||||
KCONFIG_MODE = "--allnoconfig"
|
||||
|
||||
require recipes-kernel/linux/linux-yocto.inc
|
||||
|
||||
LINUX_VERSION ?= "5.10.1"
|
||||
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
||||
|
||||
DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
|
||||
DEPENDS += "openssl-native util-linux-native"
|
||||
|
||||
KMETA = "kernel-meta"
|
||||
KCONF_BSP_AUDIT_LEVEL = "2"
|
||||
|
||||
SRCREV_machine_qemuarm ?= "24ca6a279d74e25bd07323bb901614d77e88fa2c"
|
||||
SRCREV_machine ?= "77592e956cc9cf420b17381e1b43f116395d37b3"
|
||||
SRCREV_meta ?= "1c2727e4bf30f06e6135ef59999b53cf465f6371"
|
||||
|
||||
PV = "${LINUX_VERSION}+git${SRCPV}"
|
||||
|
||||
SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;branch=${KBRANCH};name=machine \
|
||||
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.10;destsuffix=${KMETA}"
|
||||
|
||||
COMPATIBLE_MACHINE = "qemux86|qemux86-64|qemuarm|qemuarmv5"
|
||||
|
||||
# Functionality flags
|
||||
KERNEL_FEATURES = ""
|
||||
|
||||
KERNEL_DEVICETREE_qemuarmv5 = "versatile-pb.dtb"
|
||||
55
meta/recipes-kernel/linux/linux-yocto_5.10.bb
Normal file
55
meta/recipes-kernel/linux/linux-yocto_5.10.bb
Normal file
@@ -0,0 +1,55 @@
|
||||
KBRANCH ?= "v5.10/standard/base"
|
||||
|
||||
require recipes-kernel/linux/linux-yocto.inc
|
||||
|
||||
# board specific branches
|
||||
KBRANCH_qemuarm ?= "v5.10/standard/arm-versatile-926ejs"
|
||||
KBRANCH_qemuarm64 ?= "v5.10/standard/qemuarm64"
|
||||
KBRANCH_qemumips ?= "v5.10/standard/mti-malta32"
|
||||
KBRANCH_qemuppc ?= "v5.10/standard/qemuppc"
|
||||
KBRANCH_qemuriscv64 ?= "v5.10/standard/base"
|
||||
KBRANCH_qemux86 ?= "v5.10/standard/base"
|
||||
KBRANCH_qemux86-64 ?= "v5.10/standard/base"
|
||||
KBRANCH_qemumips64 ?= "v5.10/standard/mti-malta64"
|
||||
|
||||
SRCREV_machine_qemuarm ?= "6f80f1148c616a91d5384c5184c4baa40913bc72"
|
||||
SRCREV_machine_qemuarm64 ?= "77592e956cc9cf420b17381e1b43f116395d37b3"
|
||||
SRCREV_machine_qemumips ?= "8036bb43e87a6071a7f1c6d8b8a7db9c6b6e6343"
|
||||
SRCREV_machine_qemuppc ?= "77592e956cc9cf420b17381e1b43f116395d37b3"
|
||||
SRCREV_machine_qemuriscv64 ?= "77592e956cc9cf420b17381e1b43f116395d37b3"
|
||||
SRCREV_machine_qemux86 ?= "77592e956cc9cf420b17381e1b43f116395d37b3"
|
||||
SRCREV_machine_qemux86-64 ?= "77592e956cc9cf420b17381e1b43f116395d37b3"
|
||||
SRCREV_machine_qemumips64 ?= "a3de5b3de3e9c21a277818694b44fa03472a8939"
|
||||
SRCREV_machine ?= "77592e956cc9cf420b17381e1b43f116395d37b3"
|
||||
SRCREV_meta ?= "1c2727e4bf30f06e6135ef59999b53cf465f6371"
|
||||
|
||||
# remap qemuarm to qemuarma15 for the 5.8 kernel
|
||||
# KMACHINE_qemuarm ?= "qemuarma15"
|
||||
|
||||
SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;name=machine;branch=${KBRANCH}; \
|
||||
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.10;destsuffix=${KMETA}"
|
||||
|
||||
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
||||
LINUX_VERSION ?= "5.10.1"
|
||||
|
||||
DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
|
||||
DEPENDS += "openssl-native util-linux-native"
|
||||
DEPENDS += "gmp-native"
|
||||
|
||||
PV = "${LINUX_VERSION}+git${SRCPV}"
|
||||
|
||||
KMETA = "kernel-meta"
|
||||
KCONF_BSP_AUDIT_LEVEL = "1"
|
||||
|
||||
KERNEL_DEVICETREE_qemuarmv5 = "versatile-pb.dtb"
|
||||
|
||||
COMPATIBLE_MACHINE = "qemuarm|qemuarmv5|qemuarm64|qemux86|qemuppc|qemumips|qemumips64|qemux86-64|qemuriscv64"
|
||||
|
||||
# Functionality flags
|
||||
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc"
|
||||
KERNEL_FEATURES_append = " ${KERNEL_EXTRA_FEATURES}"
|
||||
KERNEL_FEATURES_append_qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
|
||||
KERNEL_FEATURES_append_qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
||||
KERNEL_FEATURES_append_qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
||||
KERNEL_FEATURES_append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
|
||||
KERNEL_FEATURES_append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
|
||||
Reference in New Issue
Block a user