Add KDE Connect recipe

classes/cmake_kdeapp.bbclass

@@ -0,0 +1,46 @@
+inherit cmake_qt5
+inherit gettext
+inherit python3native
+inherit kdoctools
+
+EXTRA_OECMAKE += " \
+    -DBUILD_TESTING=OFF \
+"
+
+DEPENDS += " \
+    extra-cmake-modules \
+    qtbase \
+    gettext-native \
+"
+
+do_configure_prepend() {
+    # kpackagetool5 needs to find installed service type files
+    export XDG_DATA_DIRS=${STAGING_DATADIR}:$XDG_DATA_DIRS
+}
+
+FILES_${PN} += " \
+    ${libdir}/libkdeinit5_*.so \
+    ${libdir}/kconf_update_bin/* \
+    ${libdir}/plugins/*.so \
+    ${libdir}/plugins/*/*.so \
+    ${libdir}/plugins/*/*/*.so \
+    ${datadir}/config.kcfg/*.kcfg \
+    ${datadir}/dbus-1/services/*.service \
+    ${datadir}/dbus-1/system-services/*.service \
+    ${datadir}/icons/hicolor \
+    ${datadir}/kconf_update/* \
+    ${datadir}/knotifications5/*.notifyrc \
+    ${datadir}/kservices5/*.desktop \
+    ${datadir}/kservices5/*.protocol \
+    ${datadir}/kservicetypes5/*.desktop \
+    ${datadir}/kxmlgui5/*/*.rc \
+    ${datadir}/metainfo/*.xml \
+    ${datadir}/polkit-1/actions/*.policy \
+"
+
+FILES_${PN}-dev += " \
+    ${datadir}/dbus-1/interfaces/*.xml \
+    ${datadir}/kdevappwizard/templates/*.tar.bz2 \
+    ${libdir}/cmake/*/*.cmake \
+    ${prefix}/mkspecs/modules/qt_*.pri \
+"

recipes-extragear/network/kdeconnect-kde.inc

@@ -0,0 +1,33 @@
+DESCRIPTION = "KDE Connect"
+HOMEPAGE = "https://community.kde.org/KDEConnect"
+LICENSE = "GPL-2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+PR = "r0"
+
+DEPENDS += " \
+    qtdeclarative \
+    qca \
+    ki18n \
+    kconfigwidgets \
+    kdbusaddons \
+    kiconthemes \
+    knotifications \
+    kio \
+    kcmutils \
+    kirigami \
+    kpeople \
+    kwayland \
+"
+
+SRC_URI = "git://anongit.kde.org/${BPN};protocol=git"
+S = "${WORKDIR}/git"
+
+inherit cmake_kdeapp
+
+EXTRA_OECMAKE += " -DEXPERIMENTALAPP_ENABLED=ON -DSMSAPP_ENABLED=ON -DOE_QCA_PATH_HOST_ROOT=${STAGING_DIR_HOST}"
+
+FILES_${PN} += " \
+    ${libdir}/qml \
+    ${datadir}/plasma \
+    ${datadir}/nautilus-python \
+"

recipes-extragear/network/kdeconnect-kde_1.3.3.bb

@@ -0,0 +1,2 @@
+require ${BPN}.inc
+SRCREV = "v${PV}"