audacity: initial add 2.4.2

Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>

recipes-musicians/audacity/audacity.bb

@@ -0,0 +1,52 @@
+SUMMARY = "Audacity is an easy-to-use, multi-track audio editor and recorder"
+HOMEPAGE = "https://www.audacityteam.org/"
+LICENSE = "GPL-2.0 & CC-BY-3.0"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=549b88b1c547acbec8f9e262f30b573e"
+
+PV = "2.4.2"
+SRC_URI = " \
+    git://github.com/audacity/audacity.git \
+    file://0001-Do-not-ask-git-for-version-information-it-breaks-bui.patch \
+"
+SRCREV ="16d52f63a4183bba77ef7305d14622958dc0d1d5"
+S = "${WORKDIR}/git"
+
+DEPENDS = " \
+    wxwidgets \
+    lame \
+    soxr \
+    portaudio-v19 \
+    portmidi \
+    alsa-lib \
+    jack \
+    libid3tag \
+    ffmpeg \
+    libmad \
+    vamp-plugin-sdk \
+    libogg \
+    libvorbis \
+    flac \
+    lv2 \
+    lilv \
+    serd \
+    sord \
+    sratom \
+    suil \
+    soundtouch \
+"
+
+inherit cmake python3native gettext gtk-icon-cache mime mime-xdg
+
+do_configure_append() {
+    # do set version 
+    # see 0001-Do-not-ask-git-for-version-information-it-breaks-bui.patch
+    # and ${S}/cmake-proxies/cmake-modules/Version.cmake. Think it erros out 
+    # because it assumes execution in source dir
+    cd ${S}
+    git show -s "--format=#define REV_LONG \"%H\"%n#define REV_TIME \"%cd\"%n" >> ${B}/src/private/RevisionIdent.h
+}
+
+FILES_${PN} += " \
+    ${datadir}/appdata \
+    ${datadir}/mime \
+"

recipes-musicians/audacity/audacity/0001-Do-not-ask-git-for-version-information-it-breaks-bui.patch

@@ -0,0 +1,33 @@
+From f14857a1889201583b1ba4a054537e8a48277079 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Andreas=20M=C3=BCller?= <schnitzeltony@gmail.com>
+Date: Sat, 19 Dec 2020 19:39:45 +0100
+Subject: [PATCH] Do not ask git for version information - it breaks build
+MIME-Version: 1.0
+Content-Type: text/plain; charset=UTF-8
+Content-Transfer-Encoding: 8bit
+
+We sit on a tagged version anyway
+
+Upstream-Status: Inapproprate [OE-specific]
+
+Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
+---
+ CMakeLists.txt | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index 4ff543049..3b0116fa9 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -125,7 +125,7 @@ endif()
+ set( GIT_COMMIT_SHORT "unknown" )
+ set( GIT_COMMIT_LONG "unknown" )
+ set( GIT_COMMIT_TIME "unknown" )
+-find_package( Git QUIET )
++#find_package( Git QUIET )
+ if( GIT_FOUND )
+    execute_process(
+       COMMAND
+-- 
+2.26.2
+

recipes-support/packagegroups/musicians-world.bb

@@ -13,6 +13,7 @@ RDEPENDS_${PN} += " \
     amsynth-standalone amsynth-lv2 amsynth-vst \
     ardour \
     aubio \
+    audacity \
     audio-tweaks \
     bristol \
     calf \