ir.lv2: initial add 1.2.4 (zero-latency) / 1.3.4 (automatable)

Tried hard but: DO NOT USE BOTH VARIANTS IN SAME DAW PROJECT

Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>

recipes-musicians/ir.lv2/files/0001-Makefile-Do-not-add-usr-include-to-include-paths.patch

@@ -0,0 +1,40 @@
+From 2cb90fd46943517f271a666f6c258bcea89e82af Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Andreas=20M=C3=BCller?= <schnitzeltony@gmail.com>
+Date: Sun, 1 Sep 2019 23:39:49 +0200
+Subject: [PATCH] Makefile: Do not add /usr/include to include paths
+MIME-Version: 1.0
+Content-Type: text/plain; charset=UTF-8
+Content-Transfer-Encoding: 8bit
+
+Upstream-Status: Pending
+
+Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
+---
+ Makefile | 4 ++--
+ 1 file changed, 2 insertions(+), 2 deletions(-)
+
+diff --git a/Makefile b/Makefile
+index 031f865..39ae139 100644
+--- a/Makefile
++++ b/Makefile
+@@ -20,7 +20,7 @@ CC ?= gcc
+ CXX ?= g++
+ 
+ # change "-O2 -ffast-math" to "-g -O0" below if you want to debug the plugin
+-CPPFLAGS += -Wall -I. -I/usr/include `pkg-config --cflags gtk+-2.0` `pkg-config --cflags gthread-2.0` -D__STDC_FORMAT_MACROS -O2 -ffast-math
++CPPFLAGS += -Wall -I. `pkg-config --cflags gtk+-2.0` `pkg-config --cflags gthread-2.0` -D__STDC_FORMAT_MACROS -O2 -ffast-math
+ LIBS += -lc -lm -lzita-convolver -lsamplerate -lsndfile `pkg-config --libs gthread-2.0` `pkg-config --libs gtk+-2.0`
+ 
+ ifeq ($(shell pkg-config --atleast-version='2.16' gtk+-2.0; echo $$?), 1)
+@@ -31,7 +31,7 @@ ifeq ($(shell pkg-config --atleast-version='2.20' gtk+-2.0; echo $$?), 0)
+    CPPFLAGS += -D_HAVE_GTK_ATLEAST_2_20
+ endif
+ 
+-C4CFLAGS = -Wall -I. -I/usr/include `pkg-config --cflags gthread-2.0` -O2 -ffast-math
++C4CFLAGS = -Wall -I. `pkg-config --cflags gthread-2.0` -O2 -ffast-math
+ C4LIBS = -lsndfile `pkg-config --libs gthread-2.0`
+ 
+ all: ir.so ir_gui.so
+-- 
+2.21.0
+

recipes-musicians/ir.lv2/files/0002-Makefile-force-correct-installation.patch

@@ -0,0 +1,35 @@
+From 32881acc0258680b3f61e2e8ea532223eb4db353 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Andreas=20M=C3=BCller?= <schnitzeltony@gmail.com>
+Date: Sun, 1 Sep 2019 23:45:26 +0200
+Subject: [PATCH] Makefile: force correct installation
+MIME-Version: 1.0
+Content-Type: text/plain; charset=UTF-8
+Content-Transfer-Encoding: 8bit
+
+Upstream-Status: Pending
+
+Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
+---
+ Makefile | 5 -----
+ 1 file changed, 5 deletions(-)
+
+diff --git a/Makefile b/Makefile
+index 031f865..a843428 100644
+--- a/Makefile
++++ b/Makefile
+@@ -7,12 +7,7 @@
+ BUNDLE = ir.lv2
+ PREFIX ?= /usr
+ 
+-user = $(shell whoami)
+-ifeq ($(user),root)
+ INSTDIR ?= $(DESTDIR)$(PREFIX)/lib/lv2
+-else 
+-INSTDIR ?= ~/.lv2
+-endif
+ 
+ INST_FILES = ir.so ir_gui.so ir.ttl manifest.ttl
+ 
+-- 
+2.21.0
+

recipes-musicians/ir.lv2/ir.lv2-automatable.bb

@@ -0,0 +1,10 @@
+require ir.lv2.inc
+
+SUMMARY = "IR LV2 convolution reverb (automatable)"
+
+IR_LV2_BRANCH = "automatable"
+SRCREV = "a523bba0f336d26197b271b64799c4f369e487a8"
+PV = "1.3.4+git${SRCPV}"
+
+IR_LV2_VARIANT = "auto"
+IR_LV2_DOAP_EXTENSION = "automatable"

recipes-musicians/ir.lv2/ir.lv2-zero-latency.bb

@@ -0,0 +1,10 @@
+require ir.lv2.inc
+
+SUMMARY = "IR LV2 convolution reverb (zero-latency)"
+
+IR_LV2_BRANCH = "zero-latency"
+SRCREV = "38bf3ec7d370d8234dd55be99c14cf9533b43c60"
+PV = "1.2.4+git${SRCPV}"
+
+IR_LV2_VARIANT = "zero"
+IR_LV2_DOAP_EXTENSION = "zero-latency"

recipes-musicians/ir.lv2/ir.lv2.inc

@@ -0,0 +1,40 @@
+HOMEPAGE = "http://tomszilagyi.github.io/plugins/ir.lv2/"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+inherit pkgconfig
+
+DEPENDS += " \
+    gtk+ \
+    lv2 \
+    libsndfile1 \
+    libsamplerate0 \
+    zita-convolver \
+"
+
+SRC_URI = " \
+    git://github.com/tomszilagyi/ir.lv2.git;branch=${IR_LV2_BRANCH} \
+    file://0001-Makefile-Do-not-add-usr-include-to-include-paths.patch \
+    file://0002-Makefile-force-correct-installation.patch \
+"
+S = "${WORKDIR}/git"
+
+LV2_NAME = "http://tomszilagyi.github.io/plugins/lv2/ir"
+IR_LV2_VARIANT ?= ""
+IR_LV2_DOAP_EXTENSION ?= ""
+
+do_compile_prepend() {
+    sed -i 's|${LV2_NAME}|${LV2_NAME}_${IR_LV2_VARIANT}|g' `grep -rl '${LV2_NAME}'`
+    sed -i 's|ir.so|ir_${IR_LV2_VARIANT}.so|g' `grep -rl ir.so`
+    sed -i 's|ir_gui.so|ir_gui_${IR_LV2_VARIANT}.so|g' `grep -rl ir_gui.so`
+}
+
+do_install() {
+    DESTDIR=${D} PREFIX=${prefix} oe_runmake install
+    mv ${D}${libdir}/lv2/ir.lv2 ${D}${libdir}/lv2/ir_${IR_LV2_VARIANT}.lv2
+    mv ${D}${libdir}/lv2/ir_${IR_LV2_VARIANT}.lv2/ir.ttl ${D}${libdir}/lv2/ir_${IR_LV2_VARIANT}.lv2/ir_${IR_LV2_VARIANT}.ttl 
+    sed -i 's|ir.ttl|ir_${IR_LV2_VARIANT}.ttl|g' ${D}${libdir}/lv2/ir_${IR_LV2_VARIANT}.lv2/manifest.ttl
+    sed -i 's|doap:name "IR"|doap:name "IR (${IR_LV2_DOAP_EXTENSION})"|g' ${D}${libdir}/lv2/ir_${IR_LV2_VARIANT}.lv2/ir_${IR_LV2_VARIANT}.ttl
+}
+
+FILES_${PN} += "${libdir}/lv2/"

recipes-support/packagegroups/musicians-world.bb

@@ -59,6 +59,7 @@ RDEPENDS_${PN} += " \
     helm-standalone helm-lv2 helm-vst \
     hydrogen hydrogen-drumkits \
     infamousplugins \
+    ir.lv2-automatable ir.lv2-zero-latency \
     \
     \
     clthreads \