Add Liri recipes

Hawaii, Papyros and Liri Project joined forces and merged their
efforts and formed Liri.

Replace Hawaii with Liri.

Signed-off-by: Pier Luigi Fiorini <pierluigi.fiorini@gmail.com>

classes/liri.bbclass

@@ -0,0 +1,15 @@
+LIRI_GIT_BRANCH ?= "develop"
+
+BPN := "${@'${BPN}'.replace('liri-', '')}"
+SRC_URI = "git://github.com/lirios/${BPN}.git;protocol=git;branch=${LIRI_GIT_BRANCH}"
+
+DEPENDS += "qtbase qtdeclarative extra-cmake-modules-native"
+
+inherit cmake_qt5 cmake_extra_sanity pkgconfig
+
+EXTRA_OECMAKE += " \
+    -DQML_INSTALL_DIR=${OE_QMAKE_PATH_QML} \
+    -DECM_MKSPECS_INSTALL_DIR=${OE_QMAKE_PATH_QT_ARCHDATA}/mkspecs/modules \
+    -DPLUGIN_INSTALL_DIR=${OE_QMAKE_PATH_PLUGINS} \
+    -DQT_PLUGIN_INSTALL_DIR=${OE_QMAKE_PATH_PLUGINS} \
+"

recipes-liri/fluid/fluid_git.bb

@@ -0,0 +1,25 @@
+SUMMARY = "A collection of cross-platform QtQuick components for building fluid and dynamic applications"
+LICENSE = "MPLv2"
+LIC_FILES_CHKSUM = " \
+    file://LICENSE.MPL2;md5=815ca599c9df247a0c7f619bab123dad \
+"
+
+inherit liri
+
+PV = "0.9.0+git${SRCPV}"
+
+SRCREV = "87d81835c38cd59dd4c717ec96ba79e32a7019ea"
+S = "${WORKDIR}/git"
+
+DEPENDS += " \
+    qtgraphicaleffects \
+    qtquickcontrols2 \
+    qtsvg \
+"
+
+do_configure_append() {
+    (cd ${S} && ./scripts/fetch_icons.sh)
+}
+
+FILES_${PN} += "${OE_QMAKE_PATH_QML}"
+FILES_${PN}-dev += "${libdir}/cmake"

recipes-liri/liri-appcenter/liri-appcenter_git.bb

@@ -0,0 +1,22 @@
+SUMMARY = "Software store"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = " \
+	file://LICENSE.GPLv3;md5=7702f203b58979ebbc31bfaeb44f219c \
+"
+
+inherit liri
+
+REQUIRED_DISTRO_FEATURES = "flatpak"
+
+PV = "0.1.0+git${SRCPV}"
+
+SRCREV = "7eef3bfea5757a38bc8e98b576f489d0a80c3d6e"
+S = "${WORKDIR}/git"
+
+DEPENDS += " \
+    flatpak \
+    karchive \
+    vibe \
+"
+
+FILES_${PN} += "${OE_QMAKE_PATH_QML} ${datadir}"

recipes-liri/liri-browser/liri-browser_git.bb

@@ -0,0 +1,18 @@
+SUMMARY = "Web browser"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = " \
+	file://LICENSE.GPLv3;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+"
+
+inherit liri
+
+PV = "0.1.0+git${SRCPV}"
+
+SRCREV = "1af85364ec3656c1e2dfe7cf3d8cffac8a022237"
+S = "${WORKDIR}/git"
+
+DEPENDS += " \
+    slimeengine \
+    qtwebengine \
+    fluid \
+"

recipes-liri/liri-files/liri-files_git.bb

@@ -0,0 +1,26 @@
+SUMMARY = "File manager"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = " \
+	file://LICENSE.GPLv3;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+"
+
+inherit liri
+
+PV = "0.1.0+git${SRCPV}"
+
+SRCREV = "1e130e882f76194b5143af5a4d26eec23ca27f3c"
+S = "${WORKDIR}/git"
+
+DEPENDS += " \
+    qttools \
+    taglib \
+    fluid \
+"
+
+EXTRA_OECMAKE += "-DQt5LinguistTools_DIR=${STAGING_LIBDIR_NATIVE}/cmake/Qt5LinguistTools"
+
+FILES_${PN} += "${OE_QMAKE_PATH_QML} ${datadir}"
+
+RREPLACES_${PN} = "swordfish"
+RPROVIDES_${PN} = "swordfish"
+RCONFLICTS_${PN} = "swordfish"

recipes-liri/liri-settings/liri-settings_git.bb

@@ -0,0 +1,46 @@
+SUMMARY = "Settings application for Liri OS"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = " \
+	file://LICENSE.GPLv3;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+"
+
+inherit liri distro_features_check
+
+REQUIRED_DISTRO_FEATURES = "wayland"
+
+PV = "0.10.0+git${SRCPV}"
+
+SRCREV = "ccb496d42cabdf43728b93024fba323682f24c33"
+S = "${WORKDIR}/git"
+
+DEPENDS += " \
+    liri-wayland \
+    qtquickcontrols \
+    vibe \
+    qtaccountsservice \
+    polkit-qt-1 \
+    xkeyboard-config \
+"
+
+EXTRA_OECMAKE += "-DQt5LinguistTools_DIR=${STAGING_LIBDIR_NATIVE}/cmake/Qt5LinguistTools"
+
+FILES_${PN} += " \
+    ${datadir}/liri/settings \
+    ${OE_QMAKE_PATH_QML} \
+"
+
+FILES_${PN}-dbg += " \
+    ${OE_QMAKE_PATH_QML}/Liri/*/.debug \
+"
+
+FILES_${PN}-dev += " \
+    ${libdir}/cmake \
+"
+
+# cross libs / headers
+CMAKE_ALIGN_SYSROOT[1] = "LiriSettings, -S${libdir}/lib, -S${STAGING_LIBDIR}/lib"
+CMAKE_ALIGN_SYSROOT[2] = "LiriSettings, -S${includedir}, -S${STAGING_INCDIR}"
+
+RREPLACES_${PN} = "hawaii-system-preferences"
+RPROVIDES_${PN} = "hawaii-system-preferences"
+RCONFLICTS_${PN} = "hawaii-system-preferences"

recipes-liri/liri-shell/files/0001-find-host-s-git.patch

@@ -0,0 +1,36 @@
+From 396f499db585e0be7029224ec6855b7f554d786f Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Andreas=20M=C3=BCller?= <schnitzeltony@googlemail.com>
+Date: Fri, 24 Apr 2015 13:29:02 +0200
+Subject: [PATCH] find host's git
+MIME-Version: 1.0
+Content-Type: text/plain; charset=UTF-8
+Content-Transfer-Encoding: 8bit
+
+we don't build git-native
+
+Upstream-Status: Inappropriate [oe-specific]
+
+Signed-off-by: Andreas Müller <schnitzeltony@googlemail.com>
+---
+ cmake/GetGitRevision.cmake | 5 ++++-
+ 1 file changed, 4 insertions(+), 1 deletion(-)
+
+diff --git a/cmake/GetGitRevision.cmake b/cmake/GetGitRevision.cmake
+index 692b6c4..c2ff81e 100644
+--- a/cmake/GetGitRevision.cmake
++++ b/cmake/GetGitRevision.cmake
+@@ -33,7 +33,10 @@
+ function(create_git_head_revision_file _file _target)
+     if(IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.git)
+         if(NOT GIT_FOUND)
+-            find_package(Git QUIET)
++            execute_process(COMMAND which git
++                  OUTPUT_VARIABLE GIT_EXECUTABLE
++                  ERROR_QUIET
++                  OUTPUT_STRIP_TRAILING_WHITESPACE)
+         endif()
+ 
+         add_custom_target(gitsha1-${_target}
+-- 
+1.9.3
+

recipes-liri/liri-shell/liri-shell_git.bb

@@ -0,0 +1,56 @@
+SUMMARY = "Responsive shell for Liri OS"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = " \
+	file://LICENSE.GPLv3;md5=d32239bcb673463ab874e80d47fae504 \
+"
+
+inherit liri systemd pythonnative distro_features_check
+
+REQUIRED_DISTRO_FEATURES = "wayland pam"
+
+PV = "0.10.0+git${SRCPV}"
+
+SRC_URI += " \
+    file://0001-find-host-s-git.patch \
+"
+SRCREV = "ba7353b01c9c87c3ec8226a2f931dc8f2a72bf3b"
+S = "${WORKDIR}/git"
+
+DEPENDS += " \
+    qtaccountsservice \
+    libpam \
+    vibe \
+    liri-wayland \
+    liri-workspace \
+"
+
+EXTRA_OECMAKE += " \
+    -DSYSTEMD_USER_UNIT_DIR=${systemd_system_unitdir} \
+"
+
+SYSTEMD_SERVICE_${PN} = "liri.service"
+
+# for starter scripts
+RDEPENDS_${PN} = "qttools-tools qtwayland-plugins"
+
+# REVISIT optionals
+RRECOMMENDS_${PN} += " \
+    liri-wallpapers \
+    paper-icon-theme \
+"
+
+FILES_${PN} += " \
+    ${datadir} \
+    ${systemd_unitdir} \
+    ${OE_QMAKE_PATH_QML}/Liri \
+    ${OE_QMAKE_PATH_PLUGINS} \
+"
+
+FILES_${PN}-dbg += " \
+    ${OE_QMAKE_PATH_PLUGINS}/.debug \
+    ${OE_QMAKE_PATH_QML}/Liri/*/.debug \
+"
+
+RREPLACES_${PN} = "hawaii-shell"
+RPROVIDES_${PN} = "hawaii-shell"
+RCONFLICTS_${PN} = "hawaii-shell"

recipes-liri/liri-terminal/liri-terminal_git.bb

@@ -0,0 +1,31 @@
+SUMMARY = "Terminal emulator"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = " \
+	file://LICENSE.GPLv3;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+"
+
+inherit liri gsettings
+
+PV = "0.1.0+git${SRCPV}"
+
+SRCREV = "e6b33d1700f454e2c50f74756aa2579fc4994996"
+S = "${WORKDIR}/git"
+
+DEPENDS += " \
+    vibe \
+"
+
+FILES_${PN} += " \
+    ${datadir}/glib-2.0/schemas \
+    ${datadir}/appdata \
+    ${datadir}/applications \
+    ${OE_QMAKE_PATH_QML}/Liri/Terminal \
+"
+
+FILES_${PN}-dbg += " \
+    ${OE_QMAKE_PATH_QML}/Liri/*/.debug \
+"
+
+RREPLACES_${PN} = "hawaii-terminal"
+RPROVIDES_${PN} = "hawaii-terminal"
+RCONFLICTS_${PN} = "hawaii-terminal"

recipes-liri/liri-themes/liri-themes_git.bb

@@ -0,0 +1,35 @@
+SUMMARY = "Themes for a uniform look throughout Liri OS"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = " \
+	file://LICENSE.GPLv3;md5=d32239bcb673463ab874e80d47fae504 \
+"
+
+inherit liri
+
+PV = "0.10.0+git${SRCPV}"
+
+SRCREV = "fc69de418a2cde7a30452993b24688ad17ea9c9f"
+S = "${WORKDIR}/git"
+
+PACKAGES = " \
+    ${PN}-grub \
+    ${PN}-plymouth \
+    ${PN}-sddm \
+"
+
+RDEPENDS_${PN}-plymouth += " \
+    plymouth \
+    plymouth-set-default-theme \
+"
+RDEPENDS_${PN}-sddm += " \
+    liri-shell \
+"
+
+FILES_${PN}-grub += "/boot/grub/themes"
+FILES_${PN}-plymouth += "${datadir}/plymouth/themes"
+FILES_${PN}-sddm += "${datadir}/sddm/themes"
+
+pkg_postinst_${PN}() {
+#!/bin/sh
+plymouth-set-default-theme -R lirios
+}

recipes-liri/liri-wallpapers/liri-wallpapers_git.bb

@@ -0,0 +1,18 @@
+SUMMARY = "Wallpapers for Liri OS"
+LICENSE = "CC-BY-SA-4.0"
+LIC_FILES_CHKSUM = " \
+	file://LICENSE.CCBYSAv4;md5=eacc0b19e3fb8dd12d2e110b24be0452 \
+"
+
+inherit liri
+
+PV = "0.10.0+git${SRCPV}"
+
+SRCREV = "50935fae9989b9c99a0a18d350d841e72e6e29bc"
+S = "${WORKDIR}/git"
+
+FILES_${PN} += "${datadir}"
+
+RREPLACES_${PN} = "hawaii-wallpapers"
+RPROVIDES_${PN} = "hawaii-wallpapers"
+RCONFLICTS_${PN} = "hawaii-wallpapers"

recipes-liri/liri-wayland/liri-wayland_git.bb

@@ -0,0 +1,55 @@
+SUMMARY = "Support library to make Qt-based Wayland compositors development easier"
+LICENSE = "LGPLv3 | GPLv3"
+LIC_FILES_CHKSUM = " \
+    file://LICENSE.GPLv3;md5=d32239bcb673463ab874e80d47fae504 \
+    file://LICENSE.LGPLv3;md5=e6a600fd5e1d9cbde2d983680233ad02 \
+"
+
+inherit liri distro_features_check cmake_auto_align_paths cmake_lib
+
+REQUIRED_DISTRO_FEATURES = "wayland"
+
+PV = "0.10.0+git${SRCPV}"
+
+SRCREV = "d8c0464ceacd70266826671a6a8dcb999b471d03"
+S = "${WORKDIR}/git"
+
+DEPENDS += " \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)} \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'xcb-util-cursor libxcursor', '', d)} \
+    wayland \
+    qtwayland \
+    qtwayland-native \
+    glib-2.0 \
+    virtual/egl \
+    libinput \
+"
+
+PACKAGECONFIG ??= " \
+    ${@bb.utils.contains("DISTRO_FEATURES", "x11", "xwayland", "",d)} \
+"
+PACKAGECONFIG[kms] = "-DENABLE_EGLDEVICEINTEGRATION_KMS:BOOL=ON,-DENABLE_EGLDEVICEINTEGRATION_KMS:BOOL=OFF,drm virtual/egl"
+PACKAGECONFIG[brcm] = "-DENABLE_EGLDEVICEINTEGRATION_BRCM:BOOL=ON,-DENABLE_EGLDEVICEINTEGRATION_BRCM:BOOL=OFF"
+PACKAGECONFIG[protocols] = "-DUSE_LOCAL_WAYLAND_PROTOCOLS:BOOL=OFF,-DUSE_LOCAL_WAYLAND_PROTOCOLS:BOOL=ON,wayland-protocols"
+PACKAGECONFIG[xwayland] = "-DENABLE_XWAYLAND:BOOL=ON,-DENABLE_XWAYLAND:BOOL=OFF,libxcb,xserver-xorg-xwayland"
+
+# cross libs / headers
+CMAKE_ALIGN_SYSROOT[1] = "LiriPlatform, -S${libdir}/lib, -S${STAGING_LIBDIR}/lib"
+CMAKE_ALIGN_SYSROOT[2] = "LiriPlatform, -S${includedir}, -S${STAGING_INCDIR}"
+CMAKE_ALIGN_SYSROOT[3] = "LiriWaylandClient, -S${includedir}, -S${STAGING_INCDIR}"
+CMAKE_ALIGN_SYSROOT[4] = "LiriWaylandServer, -S${includedir}, -S${STAGING_INCDIR}"
+
+FILES_${PN} += " \
+    ${OE_QMAKE_PATH_PLUGINS} \
+    ${OE_QMAKE_PATH_QML}/Liri \
+"
+
+FILES_${PN}-dbg += " \
+    ${OE_QMAKE_PATH_PLUGINS}/.debug \
+    ${OE_QMAKE_PATH_QML}/Liri/*/.debug \
+"
+
+FILES_${PN}-dev += " \
+    ${libdir}/cmake \
+    ${OE_QMAKE_PATH_QT_ARCHDATA}/mkspecs \
+"

recipes-liri/liri-workspace/liri-workspace_git.bb

@@ -0,0 +1,35 @@
+SUMMARY = "Workspace, programs and plugins for Liri OS"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = " \
+	file://LICENSE.GPLv3;md5=d32239bcb673463ab874e80d47fae504 \
+"
+
+inherit liri gsettings
+
+PV = "0.10.0+git${SRCPV}"
+
+SRCREV = "8ad42e0d334abee991dfebb9381d728def5330b3"
+S = "${WORKDIR}/git"
+
+DEPENDS += " \
+    liri-wayland \
+    vibe \
+    paper-icon-theme \
+    qt-gstreamer \
+    dconf \
+"
+
+EXTRA_OECMAKE += " \
+    -DSYSTEMD_USER_UNIT_DIR=${systemd_system_unitdir} \
+"
+
+FILES_${PN} += " \
+    ${datadir}/glib-2.0 \
+    ${datadir}/desktop-directories \
+    ${datadir}/liri-workspace/translations/*.qm \
+    ${OE_QMAKE_PATH_PLUGINS} \
+"
+
+RREPLACES_${PN} = "hawaii-baseapps hawaii-workspace"
+RPROVIDES_${PN} = "hawaii-baseapps hawaii-workspace"
+RCONFLICTS_${PN} = "hawaii-baseapps hawaii-workspace"

recipes-liri/packagegroups/liri-world.bb

@@ -0,0 +1,21 @@
+SUMMARY = "Liri OS package collection"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=4d92cd373abda3937c2bc47fbc49d690"
+
+inherit packagegroup
+
+RDEPENDS_${PN} = " \
+    fluid \
+    vibe \
+    qtaccountsservice \
+    paper-icon-theme \
+    ${@bb.utils.contains("DISTRO_FEATURES", "wayland", "liri-wayland", "",d)} \
+    ${@bb.utils.contains("DISTRO_FEATURES", "wayland", "liri-shell", "",d)} \
+    ${@bb.utils.contains("DISTRO_FEATURES", "wayland", "liri-workspace", "",d)} \
+    ${@bb.utils.contains("DISTRO_FEATURES", "wayland", "liri-settings", "",d)} \
+    ${@bb.utils.contains("DISTRO_FEATURES", "flatpak", "liri-appcenter", "",d)} \
+    liri-files \
+    liri-terminal \
+"
+
+LAYERDEPENDS_meta-qt5-extra += "gnome-layer"

recipes-liri/paper-icon-theme/paper-icon-theme_1.4.0.bb

@@ -0,0 +1,15 @@
+SUMMARY = "Paper is an icon theme for GTK based desktops and fits perfectly the paper-gtk-theme"
+LICENSE = "CC-BY-SA-4.0"
+LIC_FILES_CHKSUM = " \
+    file://LICENSE;md5=4a312f184ff2ceafe9466cbb7ea43f4e \
+"
+
+inherit allarch autotools
+
+SRC_URI = "https://github.com/snwh/${BPN}/archive/v${PV}.tar.gz"
+SRC_URI[md5sum] = "076e1dfa1bc5928f4c6616ffd933926a"
+SRC_URI[sha256sum] = "b90f3a84634572bcba76cdd0c2a0d305a5c521c2054d3d390edffda5f233928b"
+
+B = "${S}"
+
+FILES_${PN} += "${datadir}/icons"

recipes-liri/qtaccountsservice/qtaccountsservice_git.bb

@@ -0,0 +1,19 @@
+SUMMARY = "Qt-style API to use freedesktop.org's AccountsService DBus service"
+LICENSE = "LGPLv3"
+LIC_FILES_CHKSUM = " \
+    file://LICENSE.LGPLv3;md5=e6a600fd5e1d9cbde2d983680233ad02 \
+"
+
+inherit liri
+
+PV = "0.7.0+git${SRCPV}"
+
+SRCREV = "b1440d98c272cc1890378f44baa4631a8afb40db"
+S = "${WORKDIR}/git"
+
+FILES_${PN} += "${OE_QMAKE_PATH_QML}/QtAccountsService"
+FILES_${PN}-dbg += "${OE_QMAKE_PATH_QML}/QtAccountsService/.debug"
+FILES_${PN}-dev += "${libdir}/cmake"
+
+CMAKE_ALIGN_SYSROOT[1] = "QtAccountsService, -S${includedir}, -S${STAGING_INCDIR}"
+CMAKE_ALIGN_SYSROOT[2] = "QtAccountsService, -S${libdir}/lib, -S${STAGING_LIBDIR}/lib"

recipes-liri/vibe/vibe_git.bb

@@ -0,0 +1,33 @@
+SUMMARY = "A collection of core classes used throught Liri"
+LICENSE = "LGPLv3"
+LIC_FILES_CHKSUM = " \
+    file://LICENSE.LGPLv3;md5=e6a600fd5e1d9cbde2d983680233ad02 \
+"
+
+inherit liri distro_features_check
+
+REQUIRED_DISTRO_FEATURES = "pulseaudio"
+
+PV = "0.9.0+git${SRCPV}"
+
+SRCREV = "a2a8337b5356dd98e4ee2cfd424581b8ae2f4723"
+S = "${WORKDIR}/git"
+
+DEPENDS += " \
+    solid \
+    kwallet \
+    networkmanager-qt \
+    modemmanager-qt \
+    networkmanager \
+    modemmanager \
+    pulseaudio \
+    libqtxdg \
+    fluid \
+"
+
+FILES_${PN} += "${OE_QMAKE_PATH_QML}"
+FILES_${PN}-dev += "${libdir}/cmake"
+
+RREPLACES_${PN} = "libhawaii"
+RPROVIDES_${PN} = "libhawaii"
+RCONFLICTS_${PN} = "libhawaii"

recipes-support/packagegroups/meta-qt5-extra-world.bb

@@ -74,6 +74,7 @@ RDEPENDS_${PN} = " \
     xapian-core \
     \
     hawaii-world \
+    liri-world \
     kde-world \
     lxqt-world \
 "