hexter: initial add 1.0.3

much stolen from [1]

[1] http://pkgs.fedoraproject.org/cgit/rpms/hexter-dssi.git

Signed-off-by: Andreas Müller <schnitzeltony@googlemail.com>

recipes-misc/recipes-multimedia/hexter/files/hexter.desktop

@@ -0,0 +1,11 @@
+[Desktop Entry]
+Name=Hexter DSSI
+GenericName=Software Synthesizer
+Comment=Real-time software synthesizer DX7 emulator
+Icon=hexter
+Type=Application
+Exec=/usr/bin/hexter
+Terminal=false
+Categories=Audio;AudioVideo;Midi;X-Synthesis;X-Jack;
+X-Desktop-File-Install-Version=0.15
+

recipes-misc/recipes-multimedia/hexter/hexter_1.0.3.bb

@@ -0,0 +1,45 @@
+SUMMARY = "Yamaha DX7 modeling DSSI plugin"
+HOMEPAGE = "http://dssi.sourceforge.net/hexter.html"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
+
+inherit autotools pkgconfig gtk-icon-cache
+
+DEPENDS += " \
+    gtk+ \
+    dssi \
+    liblo \
+    ladspa-sdk \
+"
+
+SRC_URI = " \
+    ${SOURCEFORGE_MIRROR}/project/dssi/${BPN}/${PV}/${BPN}-${PV}.tar.bz2 \
+    file://hexter.desktop \
+    file://hexter.png \
+"
+SRC_URI[md5sum] = "4c3ffd27eecb7eabf1ffc3fe334937bb"
+SRC_URI[sha256sum] = "4d4091a73e04cdc9b39a6ad8aecaa9f122686a400b9e25f2617b6c0174547b3d"
+
+do_compile_append() {
+    cd ${S}/extra
+    $CC $CFLAGS -o tx_edit tx_edit.c -lcurses -lasound -lm ${LDFLAGS}
+}
+
+do_install_append() {
+    install -d ${D}/${datadir}/applications
+    install -m 755 ${WORKDIR}/hexter.desktop ${D}/${datadir}/applications/
+
+    install -d ${D}/${datadir}//icons/hicolor/36x36/apps
+    install -m 644 ${WORKDIR}/hexter.png ${D}/${datadir}/icons/hicolor/36x36/apps/
+
+    install -d ${D}/${bindir}
+    ln -s jack-dssi-host ${D}/${bindir}/hexter
+    install -m 755 ${S}/extra/tx_edit ${D}/${bindir}
+}
+
+FILES_${PN} += " \
+    ${libdir}/dssi \
+"
+
+# we are not linking against dssi - so
+RDEPENDS_${PN} += "dssi"