python3-pyqt5: initial add 5.8.2

This is the python3 variant of pyqt5. We are looking for native pyrcc5 so
extend to native.

Signed-off-by: Andreas Müller <schnitzeltony@googlemail.com>

recipes-misc/recipes-bindings/python3-pyqt5/0001-qtabbar.sip-fix-build-with-accessibility-disabled.patch

@@ -0,0 +1,35 @@
+From 8a2f852417414e19d060da66cd7c5cba76e43c7d Mon Sep 17 00:00:00 2001
+From: Diego Rondini <diego.rondini@kynetics.com>
+Date: Wed, 19 Jul 2017 14:17:51 +0200
+Subject: [PATCH] qtabbar.sip: fix build with accessibility disabled
+
+Upstream-Status: Submitted
+
+Signed-off-by: Diego Rondini <diego.rondini@kynetics.com>
+---
+ sip/QtWidgets/qtabbar.sip | 4 ++++
+ 1 file changed, 4 insertions(+)
+
+diff --git a/sip/QtWidgets/qtabbar.sip b/sip/QtWidgets/qtabbar.sip
+index ffe2d3b..80ad816 100644
+--- a/sip/QtWidgets/qtabbar.sip
++++ b/sip/QtWidgets/qtabbar.sip
+@@ -166,11 +166,15 @@ protected:
+ 
+ public:
+ %If (Qt_5_8_0 -)
++%If (PyQt_Accessibility)
+     QString accessibleTabName(int index) const;
+ %End
++%End
+ %If (Qt_5_8_0 -)
++%If (PyQt_Accessibility)
+     void setAccessibleTabName(int index, const QString &name);
+ %End
++%End
+ 
+ private:
+     QTabBar(const QTabBar &);
+-- 
+2.7.4
+

recipes-misc/recipes-bindings/python3-pyqt5_5.8.2.bb

@@ -0,0 +1,76 @@
+SUMMARY = "Python Qt5 Bindings"
+AUTHOR = "Phil Thomson @ riverbank.co.uk"
+HOMEPAGE = "http://riverbankcomputing.co.uk"
+SECTION = "devel/python"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=d32239bcb673463ab874e80d47fae504"
+
+SRC_URI = "\
+    https://sourceforge.net/projects/pyqt/files/PyQt5/PyQt-${PV}/PyQt5_gpl-${PV}.tar.gz \
+    file://0001-qtabbar.sip-fix-build-with-accessibility-disabled.patch \
+"
+SRC_URI[md5sum] = "c3048e9d242f3e72fd393630da1d971a"
+SRC_URI[sha256sum] = "ebd70515b30bbd6098fee29e6271a6696b1183c5530ee30e6ba9aaab195536e8"
+
+#PARALLEL_MAKE = ""
+
+inherit qmake5 python3native
+
+DEPENDS += "sip sip-native sip3-native qtbase python3"
+DEPENDS_append_class-target = "qtsvg qtwebkit"
+
+S = "${WORKDIR}/PyQt5_gpl-${PV}"
+B = "${S}"
+
+DISABLED_FEATURES = "PyQt_Desktop_OpenGL"
+
+DISABLED_FEATURES_append_arm = " PyQt_qreal_double"
+
+PYQT_MODULES = "QtCore QtGui QtNetwork QtWidgets QtSvg QtWebKit"
+PYQT_MODULES_class-native = "QtCore"
+PYQT_MODULES_aarch64 = "QtCore QtGui QtNetwork QtWidgets QtSvg"
+
+# full paths
+SYSROOTDIR = "${STAGING_DIR_HOST}"
+SYSROOTDIR_class-native = "${STAGING_DIR_NATIVE}"
+INCLUDEDIR = "${STAGING_INCDIR}"
+INCLUDEDIR_class-native = "${STAGING_INCDIR_NATIVE}"
+LIBDIR = "${STAGING_LIBDIR}"
+LIBDIR_class-native = "${STAGING_LIBDIR_NATIVE}"
+PYTHONEXEC="${bindir}/${PYTHON_PN}"
+PYTHONEXEC_class-native="${PYTHON}"
+
+do_configure() {
+    echo "py_platform = linux" > pyqt.cfg
+    echo "py_inc_dir = ${INCLUDEDIR}/python${PYTHON_BASEVERSION}${PYTHON_ABI}" >> pyqt.cfg
+    echo "py_pylib_dir = ${LIBDIR}/python${PYTHON_BASEVERSION}" >> pyqt.cfg
+    echo "py_pylib_lib = python${PYTHON_BASEVERSION}${PYTHON_ABI}" >> pyqt.cfg
+    echo "pyqt_module_dir = ${D}/${PYTHON_SITEPACKAGES_DIR}" >> pyqt.cfg
+    echo "pyqt_bin_dir = ${D}/${bindir}" >> pyqt.cfg
+    echo "pyqt_sip_dir = ${D}/${datadir}/sip/PyQt5" >> pyqt.cfg
+    echo "pyuic_interpreter = ${PYTHONEXEC}" >> pyqt.cfg
+    echo "pyqt_disabled_features = ${DISABLED_FEATURES}" >> pyqt.cfg
+    echo "qt_shared = True" >> pyqt.cfg
+    QT_VERSION=`${OE_QMAKE_QMAKE} -query QT_VERSION`
+    echo "[Qt $QT_VERSION]" >> pyqt.cfg
+    echo "pyqt_modules = ${PYQT_MODULES}" >> pyqt.cfg
+    echo yes | python3 configure.py --verbose --qmake ${OE_QMAKE_QMAKE} --configuration pyqt.cfg --sysroot ${SYSROOTDIR}
+}
+
+do_install() {
+     oe_runmake install
+}
+
+do_install_class-native() {
+     oe_runmake install
+}
+
+RDEPENDS_${PN}_append_class-target = " python3-core python3-sip"
+
+FILES_${PN} += " \
+    ${libdir}/${PYTHON_DIR}/site-packages \
+    ${datadir}/sip/PyQt5 \
+"
+
+BBCLASSEXTEND += "native nativesdk"
+